
Creación de un programa normal
Por lo general, después de haber programado una serie de sencillos programas simples en MQL4, un programador va querer hacer un proyecto más complejo, un programa que se pueda utilizar en la práctica. Los programas simples no satisfacen en algunos casos las necesidades de un programador de sistemas automáticos al menos por dos razones:

1. Un programa simple no provee a un operador, con la información necesaria sobre sus operaciones y el mercado, ni brinda herramientas de administración cómodas, haciendo que estos programas no sean lo suficientemente eficaces.

2. La forma en que se ha escrito el código, hace difícil su mejoramiento y entendimiento para desarrollos posteriores.

En esta sección le mostraremos una posible alternativa en la forma de construir un asesor experto, a la que usted pueda considerar como base para sus proyectos.
· Estructura de un programa normal
La creación de varias funciones personalizadas por el usuario en un programa, permite crear algoritmos de gran alcance y flexibilidad para procesar la información. La directiva #include permite utilizar funciones personalizadas en varios programas. De este modo, se pueden crear bibliotecas y utilizar funciones de código abierto de otros programadores. 

· Llevando la contabilidad de las órdenes 
En esta sección se ve un ejemplo de una función personalizada o definida por el usuario llamada Terminal(), que se coloca en un archivo aparte con la extensión .mqh. Este archivo se une al código principal durante la compilación, usando la directiva # include.
· Función para mostrar datos 
Vemos un ejemplo de una función personalizada o definida por el usuario que mostrara datos de la actividad del EA en la grafica actual. Esta función permite abandonar la función Comment() para mostrar un texto en la grafica. Esta función se representara como un indicador en una subventana separada de la grafica.
· Función para el seguimiento de eventos
Un operador no puede estar pendiente de todos los eventos que ocurren en el mercado. Un programa escrito en MQL4 permite detectar cualquier cambio en el mercado y en las condiciones comerciales. En la función personalizada o definida por el usuario Events() se conecta al EA usando la directiva # include y llama a otras funciones personalizadas como la función Inform(). 

· Función que calcula el volumen de las órdenes
El cálculo del volumen de una nueva orden, es una de las tareas de la gestión del dinero y del riesgo. La función personalizada Lot() es un pequeño ejemplo utilizado para este fin.
· Función que calcula la estrategia
La parte más importante de un EA, es la que define los criterios para abrir o cerrar una orden. La definición de estos criterios es la base de cualquier EA. La función personalizada Criterion() cumplirá esta función, y se conectara mediante la directiva  # include. De esta manera se verá como un EA toma decisiones en base a los valores de un indicador.
· Funciones que ejecutan la estrategia
Una vez la situación actual es analizada con la función Criterion(), es hora de ejecutar las decisiones tomadas: abrir, cerrar, modificar o eliminar una orden pendiente. Todas estas operaciones se pueden poner en funciones personalizadas separadas: Trade(), Close_All() y Open_Ord(). El StopLoss se moverá con la función personalizada Tral_Stop().
· Función para el procesado de errores
El procesado de errores es una parte integral de un EA. De esta manera se determinara como procesar los mensajes sobre errores como que el servidor este ocupado, o que no haya precios en la grafica, etc. En algunos casos, es suficiente con mostrar un mensaje de error. En otros casos, sería razonable intentar repetir la solicitud de la orden después de un cierto tiempo. Es necesario determinar como se procesara cada error. La función personalizada Errors() procesara los errores utilizando el operador switch().
Estructura de un programa normal
La característica más destacada de un programa normal, es que su estructura permite la utilización de funciones definidas por el usuario fácilmente.  Para que sea más cómodo, las funciones definidas por el usuario son colocadas en archivos separados con la extensión “.mqh” y son almacenadas en la ruta “C:\Archivos de Programa\Carpeta MetaTrader\experts\include\” 
Por lo general, un programa normal utiliza las tres funciones especiales, y estas llaman a las funciones definidas por el usuario. A su vez, las funciones definidas por el usuario, también pueden llamar a otras funciones definidas por el usuario, donde cada función, cumple una tarea específica y limitada dentro del programa. 
Un asesor experto, puede contener funciones definidas por el usuario con las más diversas características. Algunas funciones, por ejemplo, pueden dedicarse al seguimiento de eventos y gestión de datos, otras funciones se pueden dedicar a abrir y cerrar posiciones, unas terceras funciones se pueden dedicar a hacer  cálculos, por ejemplo la lógica de la estrategia, o calcular el costo de las órdenes, etc.  La decisión sobre que funciones utilizar, depende de la finalidad que tenga el asesor experto y que utilidad quiera darle el usuario.  En la figura 155, se puede ver el diagrama de la estructura de un asesor experto o EA normal, donde se utilizan funciones definidas por el usuario.

Las flechas en el diagrama muestran las relaciones entre las funciones. Por ejemplo, la función que lleva la contabilidad de las ordenes en el EA, se llama desde las funciones especiales init() y start() pero también se puede llamar desde otra parte del programa. A la derecha del diagrama, se ven las flechas que conectan entre sí a las funciones definidas por el usuario. Por ejemplo, la función que contiene la lógica de la estrategia (Funcion defining trade criteria), no es llamada desde las funciones especiales, pero si desde la función que lleva la contabilidad. L función “Data” es llamada desde la función especial deinit() y, si es necesario, también es llamada desde la función que procesa los errores, o la función que maneja la contabilidad o también la función que procesa los eventos. El archivo que contiene las variables compartidas por todas las funciones, y que está en la cabecera, no es llamado desde ninguna función, puesto que no contiene ninguna función que pueda ser llamada o ser ejecutada. Este archivo solo contiene las declaraciones de las variables globales o compartidas, por esta razón solo es una pequeña parte del EA. Para entender como es que se relacionan las diferentes partes de un EA, vamos a ver como se incluyen y crean estos archivos y en que orden.
Usando archivos externos con “include”
Si un programa contiene gran cantidad de líneas de código, es difícil encontrar y eliminar los errores. El programador tiene que desplazarse por el código muchas veces para hacer retoques al código en una o en otra parte. En estos casos es muy conveniente y cómodo dividir el código en partes, cada una como un archivo separado. En estos archivos separados se puede colocar cualquier parte del código del programa.  Es común que cada función este separada en un archivo diferente. Si varias funciones se interconectan lógicamente, un archivo incluido puede tener la descripción de todas las funciones definidas por el usuario. 
En la sección “información de una cuenta LINK” vimos un código de ejemplo (check.mq4) que protegía del uso desautorizado de un programa. En el asesor experto check.mq4 vimos una función que se encargaba de esa protección y que se llamaba Check(). En el código de un EA que vamos a ver más adelante (usualexpert.mq4), vamos a volver a usar la función Check(), pero esta vez la vamos a colocar en un archivo aparte (Check.mqh) y luego la vamos a incluir en el código principal. 
Función definida por el usuario Check()
bool Check()
Esta función devuelve TRUE si las condiciones de protección se cumplen, si no devuelve FALSE. Las condiciones para devolver TRUE son:
The conditions of using the program are considered as complied with, if:

· Si el programa es usado en una cuenta demo; 

· Si la cuenta se abre con SuperBank; 

· Si el usuario a colocado el código correcto en la variable externa Parol. 

El siguiente es el archivo Check.mqh que contiene la descripción del funcionamiento de la función Check(); 
//----------------------------------------------------------------------------------
// Check.mqh
// Este programa esta pensado para servir de ejemplo en el tutorial de MQL4. 
//----------------------------------------------------------------------------- 1 --
// Función que comprueba si es legal usar el programa
// Entradas:
// - variable global 'Parol'
// - constante local "SuperBank"
// Devuelve los valores:
// true – si las condiciones se cumplen 

// false - si las condiciones son violadas
//----------------------------------------------------------------------------- 2 --
extern int Parol=12345; // Contraseña con la que trabaja el programa real
//----------------------------------------------------------------------------- 3 --
bool Check()                           // Función definida por el usuario
  {
   if (IsDemo()==true)                 // Si la cuenta es demo
      return(true);                    // .. entonces no hay limitaciones
   if (AccountCompany()=="SuperBank")  //  Para los clientes corporativos…
      return(true);                    // …no se requiere contraseña
   int Key=AccountNumber()*2+1000001;  // Calcular la clave
   if (Parol==Key)                     // Si la contraseña esta bien..
      return(true);                    // .. .entonces se puede usar en una cuenta real.
   Inform(14);                         // Envía un informe desautorizando el uso
   return(false);                      // Sale de la función.
  }
//----------------------------------------------------------------------------- 4 --
Es fácil ver que el nombre del archivo Check.mqh es igual que el de la función Check(). Esto no es una regla de MQL4. No es necesario que sean iguales y más si nos damos cuenta que un archivo “.mqh” puede tener varias funciones a dentro. Sin embargo, es muy práctico colocar el mismo nombre a la función y al archivo.  Esto facilita enormemente el trabajo del programador. Usando el nombre de la función, sabrá que el código de esta estará en la ruta “…\experts\include\” con el mismo nombre. Para incluir un archivo externo “.mqh” debemos utilizar la directiva o palabra clave #include.
Directiva #include

	#include <Nombre del archivo>

#include " Nombre del archivo"


La directiva #include se puede colocar en cualquier parte del programa. Sin embargo por legibilidad, se debe colocar al inicio del programa. El pre compilador sustituirá #include < Nombre del archivo > (o #include "Nombre del archivo ") por el código del archivo que tenga ese nombre. 
Los corchetes menores/mayores <> significan que el archivo será tomado del directorio predeterminado “…\experts\include\”. Si el nombre de archivo se coloca en “comillas”, será buscado en el directorio actual, a saber, en el directorio que contiene el archivo principal. 
Abajo esta un asesor experto normal, usualexpert.mq4. Todos los archivos incluidos o importados, se colocan en la parte principal del programa. 
//----------------------------------------------------------------------------------------
// usualexpert.mq4
// Este código solo debe ser usado de manera educacional.
//----------------------------------------------------------------------------------- 1 --
#property copyright "Copyright © Book, 2007"
#property link      "http://AutoGraf.dp.ua"
//----------------------------------------------------------------------------------- 2 --
#include <stdlib.mqh>
#include <stderror.mqh>
#include <WinUser32.mqh>
//----------------------------------------------------------------------------------- 3 --
#include <Variables.mqh>   // Variables con descripción
#include <Check.mqh>       // Verifica la legalidad del uso
#include <Terminal.mqh>    // Función de la contabilidad
#include <Events.mqh>      // Seguimiento de los eventos
#include <Inform.mqh>      // Función de manejo de datos
#include <Trade.mqh>       // Función de operaciones
#include <Open_Ord.mqh>    // Apertura de ordenes
#include <Close_All.mqh>   // Cierre de ordenes
#include <Tral_Stop.mqh>   // Modificación de StopLoss
#include <Lot.mqh>         // Calculo de numero de lotes
#include <Criterion.mqh>   // Lógica de la estrategia
#include <Errors.mqh>      // Procesamiento de Errores
//----------------------------------------------------------------------------------- 4 --
int init()                             // Función especial 'init'
  {
   Level_old=MarketInfo(Symbol(),MODE_STOPLEVEL );// Distancia mínima
   Terminal();                         // Verifica la contabilidad de la cuenta 
   return;                             // Salida de init()
  }
//----------------------------------------------------------------------------------- 5 --
int start()                            // Función especial 'start'
  {
   if(Check()==false)                  // Si no cumple las condiciones...
      return;                          // .. termina la ejecución.
   PlaySound("tick.wav");              // Ejecuta un sonido en cada tic
   Terminal();                         // Lleva la contabilidad  
   Events();                           // Información sobre los eventos
   Trade(Criterion());                 // Ejecuta un trade si se cumplen los criterios
   Inform(0);                          // Cambia el color de los textos que llevan el informe
   return;                             // Sale de start()
  }
//----------------------------------------------------------------------------------- 6 --
int deinit()                           // Función especial deinit()
  {
   Inform(-1);                         // Elimina todos los objetos gráficos
   return;                             // Sale de deinit()
  }
//----------------------------------------------------------------------------------- 7 --
En el bloque 2 – 3 incluimos los archivos predeterminados stdlib.mqh, stderror.mqh y WinUser32.mqh usando la directiva #include. Estos archivos no son indispensables, sin embargo son una buena ayuda. Por ejemplo, el archivo stderror.mqh contiene la definición de los códigos de error, que nos hará mas fácil comprender estos códigos.  Si no se están procesando los errores en un programa, este archivo no será necesario. Pero generalmente es útil y normal incluir estos archivos. 
En el bloque 3 – 4 el programa incluye algunos archivos que contienen funciones definidas por el usuario. En la línea que esta abajo, agregamos la función Check.mqh. 
#include <Check.mqh>       // Verifica la legalidad del uso
Uno puede pensar que un código como el anterior (usualexpert.mq4) es interpretado por el compilador tal cual como se ve. Sin embargo lo que el pre compilador hace, es sustituir cada línea con la directiva #include, por el código que el archivo tiene. De esta manera, se compila todo como si fuera solo un único archivo “.mq4” que genera un archivo “.ex4”.

En general todos los archivos externos contienen funciones. Sin embargo en el código anterior hay un archivo muy importante que no tiene ninguna función ejecutable. En vez de tener una función, este archivo contiene todas las variables que se utilizaran en el programa, y que se compartirá entre todos los archivos. Este archivo se llama Variables.mqh. 
#include <Variables.mqh>   // Descripción de variables
El código de este archivo es el siguiente:
//----------------------------------------------------------------------------
// Variables.mqh
// Este código solo debe ser usado de manera educacional. 
//----------------------------------------------------------------------- 1 --
// Descripción de variables globales 
extern double Lots    = 0.0;// Cantidad de lotes
extern int Percent    = 0;  // Porcentaje de fondos asignados
extern int StopLoss   =100; // StopLoss para las nuevas órdenes en pips 
extern int TakeProfit =40;  // TakeProfit para las nuevas órdenes en pips
extern int TralingStop=100; // TralingStop para ordenes de mercado en pips
//----------------------------------------------------------------------- 2 --
int 
   Level_new,           // Nuevo valor para la mínima distancia
   Level_old,           // Previo valor para la mínima distancia
   Mas_Tip[6];          // Array con tipos de ordenes
                        // [] order type: 0=B,1=S,2=BL,3=SL,4=BS,5=SS
//----------------------------------------------------------------------- 3 --
double
   Lots_New,            // Cantidad de lotes para las nuevas ordenes
   Mas_Ord_New[31][9],  // Array con el listado de ordenes abiertas. ..
   Mas_Ord_Old[31][9];  // .. Array con ordenes previas 
                        // 1st index = Numero de ordenes abiertas 
                        // [][0] Sin datos
                        // [][1] Precio de apertura de la orden
                        // [][2] StopLoss de la orden
                        // [][3] TakeProfit de la orden
                        // [][4] Numero de la orden     
                        // [][5] Volumen de la orden (abs. Valor precio)
                        // [][6] Tipo de orden 0=B,1=S,2=BL,3=SL,4=BS,5=SS
                        // [][7] Número mágico de la orden
                        // [][8] 0/1 para saber si la orden tiene comentarios
//----------------------------------------------------------------------- 4 --
Según las reglas que maneja MQL4, las variables globales se deben declarar al inicio del código. Por esta razón, el archivo Variables.mqh se incluye al inicio del programa, y está situado por encima de los archivos que contienen las funciones que utilizaran estas variables. 

En algunos casos (raros), es técnicamente posible declarar una variable global en un archivo incluido que contenga una función, en la cual el valor de esta variable primero se utiliza en el programa. En tales casos, es necesario guardar el archivo respetando la regla de posicionamiento de las variables.

En otros casos, es incluso técnicamente imposible hacerlo. Por ejemplo, si tenemos dos archivos incluidos, cada uno de ellos con dos variables globales, una de las cuales se declara en un archivo y la otra se declara en el otro archivo, entonces se obtendrá un error al compilar un programa, ya que, independientemente del orden, una de las variables se utiliza antes de que se declare en el programa. Esta es la razón por la cual, es una práctica habitual y recomendada en los programas normales, declarar todas las variables globales, sin excepción alguna, en un único archivo, y incluirlo en el programa, antes que los otros ficheros que contengan funciones definidas por el usuario.

En el bloque 1-2 del archivo Variables.mqh, las variables externas que se declaran son las que determinan la cantidad de lotes para nuevas órdenes, también hay una variable que determina el porcentaje asignado para nuevos pedidos, también está el stoploss, el TakeProfit y el TralingStop o stop fluctuante. En el bloque 2-4, se declaran otras variables globales que se explicaran y quedaran claras más adelante. Cada archivo externo será explicado paso a paso, en los capítulos subsiguientes. 
Llevando la contabilidad de las órdenes
Llevando la contabilidad de las órdenes

Hemos mencionado anteriormente que no hay reglas estrictas para diseñar los algoritmos en los programas. Al mismo tiempo, la gran mayoría de los algoritmos tiene que tomar decisiones teniendo en cuenta las órdenes ya abiertas. En algunos casos, por ejemplo, en una estrategia solo puede haber una orden abierta por vez. En otros casos si se permite que hayan varias órdenes abiertas al mismo tiempo.  También sabemos de otros algoritmos que funcionan colocando dos órdenes pendientes en diferentes direcciones. 

Para cumplir los requisitos que exige una estrategia u otra, usted tiene que estar enterado de la situación actual. ¿Qué órdenes de mercado y órdenes pendientes están abiertas, y cuáles son sus características? Para responder esta pregunta, usted puede utilizar dos posibles soluciones. 

En la primera solución, se escribe el fragmento de código que responde a esta pregunta, en cada lugar donde se necesite. Esta solución es técnicamente viable, pero resulta ser ineficiente, si desea hacer cambios en el algoritmo. En este caso, el programador tiene que buscar y analizar todos los lugares donde se encuentra este código, y hacer los cambios correspondientes. La segunda solución, es crear una función universal que actualice el listado de órdenes de mercado abiertas, y que esta función se ejecute cada vez que se necesite. Por un lado, esta función permite hacer el código más corto y eficaz. Por otro lado, da la opción de reutilizar la misma función para otros programas. 

Para crear una función que lleve la contabilidad de nuestras órdenes correctamente, tenemos que saber que datos hay que calcular. En la mayoría de los casos, los valores siguientes son vitales para llevar la contabilidad y así poder tomar decisiones en base a ella:
· cantidad total de órdenes; 

· la cantidad de ordenes abiertas para cada tipo de orden (por ejemplo, la cantidad de compras, ventas , SellStop, o BuyLimit); 

· todas las características de cada orden (ticket, StopLoss y TakeProfit, lotes, etc.).. 

Esta información tiene que estar disponible para todas las funciones, en especial para las que procesan esta información. Por esta razón, toda esta información que se necesita para llevar la contabilidad tiene que estar guardada en Arrays globales. En total debe haber tres arrays para guardar esta información. 
· Un Array para llevar toda la información de las posiciones abiertas y órdenes pendientes. Este array debe contener toda la información de cada posición y debe tener la información actualizada desde la última vez que se ejecuto la función. Este array lo vamos a llamar Mas_Ord_New; 

· Un Array idéntico al anterior con la salvedad de que va a guardar la información desde la penúltima vez que se ha ejecutado esta función. Más adelante vamos a entender el porqué. Este Array lo vamos a llamar Mas_Ord_Old; 

· Un Array  llamado Mas_Tip, que nos va a servir para llevar un listado de los diferentes tipos de órdenes abiertas y la cantidad de cada tipo de orden. 

Las Arrays Mas_Ord_New y Mas_Ord_Old  son parecidas y con dimensiones equivalentes. La diferencia está en que el primero refleja el estado actual de las órdenes y el segundo refleja el estado anterior al actual. Vamos a ver en detalle la estructura de estos dos Arrays. 
Table 4. Correspondencia de los elementos de las arrays Mas_Ord_New y Mas_Ord_Old conlas características de las orden.
	
	Si datos
	Precio apertura
	StopLoss
	TakeProfit
	Numero de orden
	Volumen en lotes
	Tipo de orden
	Numero Magico
	Comentario

	Indice
	0
	1
	2
	3
	4
	5
	6
	7
	8

	0
	2.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0

	1
	0.0
	1.2583
	1.2600
	1.2550
	123456.0
	1.4
	1.0
	1177102416.0
	1.0

	2
	0.0
	1.2450
	1.2580
	1.2415
	123458.0
	2.5
	2.0
	1177103358.0
	0.0

	3
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0

	. . .
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0

	30
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0
	0.0


El primer índice del array (filas) representa el número de la orden en el array. Las propiedades de la primera orden (ordenes abiertas y ordenes pendientes) se colocan en el índice 1 (y no en el 0), las de la segunda orden en el índice 2, etc.  El tamaño del array para el primer índice es de 31 casillas, de esta manera, el array puede almacenar hasta 30 órdenes al mismo tiempo. Si su estrategia necesita tener más de 30 órdenes abiertas, deberá cambiar este número en la declaración del array. En la mayoría de los casos, la cifra de 30, supera por mucho la cifra que se necesita normalmente, que generalmente es de 2 a  10 – 15 ordenes abiertas al mismo tiempo. Colocamos la cifra de 30 en este ejemplo, porque queremos mostrar que este array puede ser útil aun, en estrategias muy inusuales.

En el segundo índice del array (columnas), se representa las propiedades de las ordenes. Por ejemplo, cada elemento del array con el índice número 1, contiene el precio en que se abrió o se va abrir una orden, en el índice 2, se encentra el StopLoss, en el 3 el TakeProfit etc (Vea el cuadro 4). En el elemento [0] [0] del array se guardaran el número total de ordenes abiertas o ordenes pendientes que hay en el array.  En los demás elementos que contienen índice 0, no hay ninguna información, exceptuando como ya dijimos el índice [0] [0]. 

En el cuadro 4, se representa un array “Mas_Ord_New” que contiene la información de dos órdenes abiertas. Como podemos ver, el elemento Mas_Ord_New[0][0] tiene el valor de 2, que representa la cantidad de ordenes abiertas en este momento.  Por ejemplo el índice 1 del array Mas_Ord_New[1] contiene la información de una orden de venta (Mas_Ord_New [1] [6] ver tipos de ordenes LINK) abierta con 1.4 lotes (Mas_Ord_New[1][5] =1.4) y con el numero 123456.0 (Mas_Ord_New[1][4] =123456.0). El valor Mas_Ord_New [1] [8] =1.0 significa que esta orden tiene un comentario agregado. En el segundo índice Mas_Ord_New[2] existe una segunda orden de tipo BuyLimit, Mas_Ord_New[2][6]. 

Veamos el tercer array Mas_Tip. Este array representa la cantidad de órdenes de cada tipo. A cada tipo de orden se le asigna su código correspondiente (ver tipos de ordenes LINK).  Esto significa que el elemento Mas_Tip [0] contiene la cantidad de órdenes de compra, Mas_Tip [1] las órdenes de venta, Mas_Tip [2] las ordenes BuyLimit y así, etc. Relacionando la tabla 4, Mas_Tip tendría la siguiente forma:

Table 5. Correspondencia de los elementos de la array Mas_Tip que contiene la cantidad de tipos de ordenes abiertas.

	
	Compra
	Venta
	BuyLimit
	SellLimit
	BuyStop
	SellStop

	Index
	0
	1
	2
	3
	4
	5

	Value
	0
	1
	1
	0
	0
	0


En este caso, Mas_Tip Mas_Tip [1] nos dice que hay una orden de venta y Mas_Tip [1] nos dice que hay una orden BuyLimit actualmente. Los demás índices que tienen el valor 0, quieren decir que no hay órdenes de su tipo abiertas. Si hay varias ordenes del mismo tipo abiertas en un momento dado, el elemento correspondiente del array tendrá la cantidad equivalente. Por ejemplo si hay 3 órdenes BuyStop, entonces el elemento Mas_Tip [4] tendrá un valor de 3. 

La función que maneja la contabilidad con estas arrays la vamos a llamar Terminal() y la incluiremos en un archivo Terminal.mqh .
Función definida por el usario Terminal()
int Terminal()
Esta función lleva la contabilidad de las órdenes abiertas y ordenes pendientes. Cuando se ejecuta esta función, se modifican las siguientes arrays globales. 
· Mas_Ord_New – El array con todas las propiedades de las ordenes, en el momento que se ejecuta la function;

· Mas_Ord_Old - El array con todas las propiedades de las ordenes, en la penúltima vez que se ha ejecutado la función; 

· Mas_Tip - El array que representa la cantidad de órdenes de cada tipo. 

El siguiente es el archivo Terminal.mqh que contiene la función Terminal();
//--------------------------------------------------------------------
// Terminal.mqh
// Este código solo debe ser usado de manera educacional. 
//------------------------------------------------------------------------------ 1 --
// Función que maneja la contabilidad de las ordenes 
// Variables globales: 
// Mas_Ord_New[31][9]   // Ultimo registro de las ordenes abiertas
// Mas_Ord_Old[31][9]   // Penúltimo registro de las ordenes abiertas
                        // 1st index = Numero de la orden en el array 
                        // [][0] Campo vacio
                        // [][1] Precio de apertura de la orden
                        // [][2] StopLoss de la orden
                        // [][3] TakeProfit de la orden
                        // [][4] Numero de la orden 
                        // [][5] Numero de lotes de la orden 
                        // [][6] Tipo de orde 0=B,1=S,2=BL,3=SL,4=BS,5=SS
                        // [][7] Número mágico de la orden 
                        // [][8] 0/1 Existencia de comentario 
// Mas_Tip[6]           // Array que representa la cantidad de órdenes de cada tipo 
                        // [] order type: 0=B,1=S,2=BL,3=SL,4=BS,5=SS
//------------------------------------------------------------------------------ 2 --
int Terminal()
  {
   int Qnt=0;                          // Contador de ordenes 
 
//------------------------------------------------------------------------------ 3 --
   ArrayCopy(Mas_Ord_Old, Mas_Ord_New);// Salvamos la info de la ultima actualización 
   Qnt=0;                              // Reiniciando contador de ordenes 
   ArrayInitialize(Mas_Ord_New,0);     // Reiniciando la array 
   ArrayInitialize(Mas_Tip,    0);     // Reiniciando la array 
//------------------------------------------------------------------------------ 4 --
   for(int i=0; i<OrdersTotal(); i++) // Ciclo que revisa todas las ordenes
     {
      if((OrderSelect(i,SELECT_BY_POS)==true)     //Si selecciona una orden..
      && (OrderSymbol()==Symbol()))               //.. y la divisa es la correcta, se continua 
        {
         //--------------------------------------------------------------------- 5 --
         Qnt++;                                   // Se suma un digito al contador 
         Mas_Ord_New[Qnt][1]=OrderOpenPrice();    // Copia el orden de apertura 
         Mas_Ord_New[Qnt][2]=OrderStopLoss();     // Copia el precio de StopLoss 
         Mas_Ord_New[Qnt][3]=OrderTakeProfit();   // Copia el precio TakeProfit 
         Mas_Ord_New[Qnt][4]=OrderTicket();       // Copia el numero de la orden 
         Mas_Ord_New[Qnt][5]=OrderLots();         // Copia el numero de lotes 
         Mas_Tip[OrderType()]++;                  // Lleva la cantidad de orden de ese tipo
         Mas_Ord_New[Qnt][6]=OrderType();         // Copia el tipo de la orden 
         Mas_Ord_New[Qnt][7]=OrderMagicNumber();  // Copia el numero magico 
         if (OrderComment()=="")
            Mas_Ord_New[Qnt][8]=0;                // Si no hay comentario 
         else
            Mas_Ord_New[Qnt][8]=1;                // Si hay comentario 
         //--------------------------------------------------------------------- 6 --
        }
     }
   Mas_Ord_New[0][0]=Qnt;                         // Registra el total de ordenes 
//------------------------------------------------------------------------------ 7 --
   return;
  }
//------------------------------------------------------------------------------ 8 --
En el bloque 1 – 2 colocamos un comentario que describe la función. Las variables se declaran en el archivo externo llamado Variables.mqh. En el bloque 3 – 4, el contenido del array Mas_Ord_New se copia al array Mas_Ord_Old. De esta manera podremos utilizar esta información más adelante en el programa. Después los datos Mas_Ord_New y Mas_Tip que llevaban la información de las órdenes se reinician, antes que se actualicen con nuevos datos en el bloque 4 - 7. 

El bloque 4 – 7  contiene un ciclo “for”, en el cual todas las ordenes y las ordenes pendientes, se revisan una por una, para saber si hay órdenes de la misma divisa de la grafica donde se coloca el EA. Las ordenes se seleccionan usando la función OrderSelect() según el parámetro MODE_TRADES que esta como predeterminado. En el bloque 5 – 6, todas las propiedades de las ordenes seleccionadas se guardan en el array Mas_Ord_New. Al mismo tiempo, el tipo de pedidos y su cantidad se almacenan en el array Mas_Tip. Después que termina el ciclo, se guarda en el elemento Mas_Ord_New [0] [0] la cantidad de órdenes totales.

Debe observarse que las ordenes cerradas y suprimidas no son tenidas en cuenta (en la función OrderSelect() no se utiliza el parámetro MODE_HISTORY). En general, la información sobre las órdenes cerradas y eliminadas no se utiliza en un EA. La información sobre las órdenes cerradas y suprimidas representa el historial de una cuenta. Esta información puede ser útil, por ejemplo, para construir gráficos que muestren el crecimiento de una cuenta en un periodo de tiempo dado. Sin embargo, no nos serán útiles a la hora de tomar decisiones para abrir o cerrar cuentas. Técnicamente la forma de tratar estos datos es similar. Sin embargo, es una tarea separada, que no tienen ninguna relación con el mercado actual.

Los eventos  relacionados con las órdenes se analizaran en un programa que se basa en los datos tratados más arriba. Por ejemplo, si el array Mas_Ord_Old contiene una orden con el numero 246810, y en cambio, el array mas reciente Mas_Ord_New, contiene una orden con el mismo numero 246810 pero de un tipo diferente de orden, esto puede significar que una orden pendiente se ha ejecutado y se ha convertido en una orden abierta. También va ser útil a la hora de crear ordenes (esto se verá más adelante). 

Cuando la función Terminal() se ejecuta por primera vez, las arrays Mas_Ord_Old y  Mas_Ord_New están vacías, es decir, las dos arrays tienen valor cero. Esto significa, que después de la primera ejecución el array Mas_Ord_Old en la línea:
   ArrayCopy(Mas_Ord_Old, Mas_Ord_New);// Salvamos la info de la última actualización
copia el valor “cero” que está en el array Mas_Ord_New, dando como resultado falsas alarmas, en la función que registra los eventos que veremos más adelante. Para prevenir esto, la primera ejecución de la función Terminal() se realiza en la inicialización, y la función que procesa los eventos no (véase la función init() en el EA usualexpert.mq4 LINK). 
Función para mostrar datos
Un consejero experto normal (EA) que se usa en la práctica, es mucho más potente que un EA simple, porque proporciona información de alta calidad.  

El mercado siempre está cambiando y a todo momento suceden cosas. Para que el operador tome decisiones acertadas, es crucial que esté completamente informado  sobre la situación del mercado. Por esta razón, un EA debe tener una función que informe al operador. Esta función debe estar destinada a informar al usuario sobre un determinado conjunto de hechos y procesos. 

En general, un EA simple cumple esta labor utilizando la función Comment() que coloca un texto informativo en la parte superior izquierda de la grafica. Este método para mostrar información no es muy cómodo, puesto que en algunas ocasiones, el texto  puede tapar la grafica del precio. Este método se puede utilizar tan solo en una cantidad limitada de casos, y solo para mostrar información corta. 

Veamos una forma diferente de mostrar información. El mensaje se mostrara en una sudventana diferente a la del precio, y esta información se mostrara con objetos gráficos. Usar objetos gráficos tiene la gran ventaja que estos se pueden mover con la grafica, (a diferencia de la función Comment()) creando así una especie de línea de tiempo.

Para crear una subventana, hay que crear un indicador personalizado. El único propósito de este indicador es la creación de la sub-ventana, y no realizara ningún tipo de cálculo, ni tampoco dibujara líneas. El código de este indicador, al que vamos a llamar Inform.mq4 se muestra a continuación:

//--------------------------------------------------------------------
// Inform.mq4 
// Este código solo debe ser usado de manera educacional. 
//--------------------------------------------------------------------
#property indicator_separate_window //  Indicador separado de la ventana 
//--------------------------------------------------------------------
int start()                         // función especial start()
  {
  }
//--------------------------------------------------------------------
En general, un programador puede colocar en el indicador el código que desee, y mejorar sus características. Por ejemplo usted puede mostrar unas líneas en una parte de la subventana. En el ejemplo anterior se muestra un código simple en que se crea una nueva subventana.
Función definida por el usuario Inform()
int Inform(int Mess_Number,int Number=0,double Value=0.0)
Esta función mostrara los objetos gráficos descritos más arriba en el indicador que vimos antes Inform.mq4. Esta función controla la posición de los objetos gráficos que se mostraran en la subventana: cada mensaje nuevo, se colocara en una línea más abajo del indicador y se coloreara con el color deseado, y las líneas anteriores se moverán a la parte superior del indicador. Si no hay actualizaciones en los datos en 15 segundos, los textos cambiaran su color a gris, para no crearle distracciones al usuario. 

Parámetros: 
Mess_Number - número del mensaje que puede tomar los siguientes valores:
· (cero) 0 - no se muestra ningún mensaje. Este valor se utilizar para reiniciar el contador del tiempo;
· (menos uno) -1 - todos los objetos gráficos creados por la función serán suprimidos;
· (uno o mayor) – Si es un número mayor que cero, este número será tomado como el numero del mensaje que se mostrara en la subventana del indicador;
Number - número entero que se usara en algunos mensajes;
Value - número real que se usara en algunos mensajes.
La función Inform() que es la que crea los objetos gráficos, la vamos a colocar en un archivo separado, como en las otras funciones en un EA normal y luego la vamos a incluir en nuestro indicador. Este archivo se llamara Inform.mqh:
//----------------------------------------------------------------------------
// Inform.mqh
// Este código solo debe ser usado de manera educacional. 
//----------------------------------------------------------------------- 1 --
// Función que muestra mensajes en objetos gráficos en la pantalla. 
//----------------------------------------------------------------------- 2 --
int Inform(int Mess_Number, int Number=0, double Value=0.0)
  {
   // int    Mess_Number               // Numero del mensaje   
   // int    Number                    // Numero entero 
   // double Value                     // Numero real 
   int    Win_ind;                     // Número de la ventana del indicador 
   string Graf_Text;                   // Texto del mensaje
   color  Color_GT;                    // Color del texto del mensaje
   static int    Time_Mess;            // Ultima fecha de publicación del mensaje
   static int    Nom_Mess_Graf;        // Numero de mensajes gráficos
   static string Name_Grf_Txt[30];     // Array con los textos de mensajes publicados 
//----------------------------------------------------------------------- 3 --
   Win_ind= WindowFind("inform");      // Buscando el numero de la ventana
   if (Win_ind<0)return;               // Si no hay tal ventana, salir 
//----------------------------------------------------------------------- 4 --
   if (Mess_Number==0)                 // Esto sucede en cada tick 
     {
      if (Time_Mess==0) return;        // Si ya es gris sale 
      if (GetTickCount()-Time_Mess>15000)// El color no ha sido actualizado en 15 seg
        {
         for(int i=0;i<=29; i++)       // Líneas de color gris 
            ObjectSet( Name_Grf_Txt[i], OBJPROP_COLOR, Gray);
         Time_Mess=0;                  // Bandera  que indica que todas las líneas son de color gris 
         WindowRedraw();               // Redibujo de los objetos 
        }
      return;                          // Salimos de la función 
     }
//----------------------------------------------------------------------- 5 --
   if (Mess_Number==-1)                // Esto se cumple en deinit()
     {
      for(i=0; i<=29; i++)             // El índice de los objetos 
         ObjectDelete(Name_Grf_Txt[i]);// Eliminación de los objetos 
      return;                          // Salimos de la función
     }
//----------------------------------------------------------------------- 6 --
   Nom_Mess_Graf++;                    // Contador de mensajes 
   Time_Mess=GetTickCount();           // La fecha del último mensaje 
   Color_GT=Lime;
//----------------------------------------------------------------------- 7 --
   switch(Mess_Number)                 // Elegir texto del mensaje según el numero 
     {
      case 1:
         Graf_Text="Closed order Buy "+ Number;
         PlaySound("Close_order.wav");                         break;
      case 2:
         Graf_Text="Closed order Sell "+ Number;
         PlaySound("Close_order.wav");                         break;
      case 3:
         Graf_Text="Deleted pending order "+ Number;
         PlaySound("Close_order.wav");                         break;
      case 4:
         Graf_Text="Opened order Buy "+ Number;
         PlaySound("Ok.wav");                                  break;
      case 5:
         Graf_Text="Opened order Sell "+ Number;
         PlaySound("Ok.wav");                                  break;
      case 6:
         Graf_Text="Placed pending order "+ Number;
         PlaySound("Ok.wav");                                  break;
      case 7:
         Graf_Text="Order "+Number+" modified into the market one";
         PlaySound("Transform.wav");                           break;
      case 8:
         Graf_Text="Reopened order "+ Number;                  break;
         PlaySound("Bulk.wav");
      case 9:
         Graf_Text="Partly closed order "+ Number;
         PlaySound("Close_order.wav");                         break;
      case 10:
         Graf_Text="New minimum distance: "+ Number;
         PlaySound("Inform.wav");                              break;
      case 11:
         Graf_Text=" Not enough money for "+
         DoubleToStr(Value,2) + " lots";
         Color_GT=Red;
         PlaySound("Oops.wav");                                break;
      case 12:
         Graf_Text="Trying to close order "+ Number;
         PlaySound("expert.wav");                              break;
      case 13:
         if (Number>0)
            Graf_Text="Trying to open order Sell..";
         else
            Graf_Text="Trying to open order Buy..";
         PlaySound("expert.wav");                              break;
      case 14:
         Graf_Text="Invalid password. EA doesn't function.";
         Color_GT=Red;
         PlaySound("Oops.wav");                                break;
      case 15:
         switch(Number)                 // Elegir texto del mensaje según el numero del error 
           {
            case 2:   Graf_Text="Common error.";                    break;
            case 129: Graf_Text="Wrong price. ";                    break;
            case 135: Graf_Text="Price changed. ";                  break;
            case 136: Graf_Text="No prices. Awaiting a new tick.."; break;
            case 146: Graf_Text="Trading subsystem is busy";        break;
            case 5 :  Graf_Text="Old version of the terminal.";     break;
            case 64:  Graf_Text="Account is blocked.";              break;
            case 133: Graf_Text="Trading is prohibited";            break;
            default:  Graf_Text="Occurred error " + Number;//otros errores 
           }
         Color_GT=Red;
         PlaySound("Error.wav");                                    break;
      case 16:
         Graf_Text="Expert Advisor works only for EURUSD";
         Color_GT=Red;
         PlaySound("Oops.wav");                                     break;
      default:
         Graf_Text="default "+ Mess_Number;
         Color_GT=Red;
         PlaySound("Bzrrr.wav");
     }
//----------------------------------------------------------------------- 8 --
   ObjectDelete(Name_Grf_Txt[29]);      // Eliminación del objeto  29 en el array 
   for(i=29; i>=1; i--)                 // Ciclo en el índice del array... 
     {                                 // .. en los objetos gráficos 
      Name_Grf_Txt[i]=Name_Grf_Txt[i-1];// Aumento de los objetos 
      ObjectSet( Name_Grf_Txt[i], OBJPROP_YDISTANCE, 2+15*i);
     }
   Name_Grf_Txt[0]="Inform_"+Nom_Mess_Graf+"_"+Symbol(); // Nombre de objeto 
   ObjectCreate (Name_Grf_Txt[0],OBJ_LABEL, Win_ind,0,0);// Creación
   ObjectSet    (Name_Grf_Txt[0],OBJPROP_CORNER, 3   );  // Esquina
   ObjectSet    (Name_Grf_Txt[0],OBJPROP_XDISTANCE, 450);// Eje Х
   ObjectSet    (Name_Grf_Txt[0],OBJPROP_YDISTANCE, 2);  // Eje Y
   // Текстовое описание объекта
   ObjectSetText(Name_Grf_Txt[0],Graf_Text,10,"Courier New",Color_GT);
   WindowRedraw();                      // Se redibujan todos los objetos. 
   return;
  }
//----------------------------------------------------------------------- 9 --
En el bloque 2 – 3 se declaran y describen las variables que se van a utilizar en la función.  Para guardar los nombres de los objetos, utilizaremos el array llamado Name_Grf_Txt. Según el parámetro colocado en la función, se crea un nuevo objeto grafico para mostrar un mensaje. La cantidad total de objetos es 30 y cada objeto representa una entrada de texto escrita en una línea. En caso de tener una resolución de pantalla grande, la cantidad máxima de objetos mostrados puede aumentar. 

En el bloque 3 – 4 se verifica que la ventana del indicador sea la correcta. Si no es la correcta, no se muestra ningún objeto grafico. Si no se ha agregado la subventana, el resto del EA funcionara correctamente, y las operaciones no serán afectadas. 

En el bloque 4 – 5, se analizan los colores de los menajes. Si a la función se le manda el parámetro Mess_Number=0 quiere decir que no hay mensajes. Si todos los objetos son grises ya, no sucede nada. Pero si el valor de Time_Mess es diferente a cero, el color de todos los objetos cambia a gris. 

Si (bloque 5 – 6) el parámetro de Mess_Number  es  -1, todos los objetos creados anteriormente se borran.  Esto puede ser necesario cuando se quita al EA de la grafica. En este caso, es común que cada programa que creo objetos gráficos, también los borre cuando se cierra el programa en la función especial deinit(). 

Si el programa llega hasta el bloque 6 – 7, significa que es necesario crear un nuevo objeto gráfico con las características requeridas y ponerlo en la parte más inferior del subwindow del indicador (“en la línea más baja”; aquí, el término “línea” es condicional. De hecho, la localización de objetos gráficos es determinada por las coordenadas que le demos). Cada objeto recién creado tiene un nombre único. Para darle el nombre a cada objeto, utilizamos el número histórico del mensaje, esta es la razón por la cual colocamos los nombres al revés en el bloque 6 – 7 (posteriormente el valor de la variable Nom_Mess_Graf se utilizara para formar un único nombre en bloque 8-9). Es acá donde se lleva la fecha de la última publicación de un mensaje y a los mensajes nuevos se le coloca el color verde. 

El bloque 7 – 8 consiste en un operador “switch” que depende del valor del mensaje que está en Mess_Number. Cada “caso” de este “switch”, representa un mensaje a mostrar, y este mensaje será copiado a la variable Graf_Text, mostrando así un mensaje apropiado según el caso.  En algunos casos también se cambia el color del texto, por ejemplo, rojo para los mensajes importantes. Todos los mensajes se acompañan con un sonido característico, que se reproducen con la función PlaySound () (ver archivos de sonido LINK).

La creación de un nuevo objeto gráfico y el reemplazo de los existentes se realiza en el bloque 8-9. La cantidad máxima de objetos gráficos es limitada, así que un objeto (el más viejo) se elimina cada vez que se publica un nuevo mensaje. El resto de los objetos se mueve una línea hacia arriba. Los objetos se mueven cambiando la propiedad que representa las coordenadas horizontales. 

Después de que se han hecho todos los cálculos (todos los objetos se han movido una línea hacia arriba), un nuevo objeto con un nombre único y con las propiedades determinadas en el bloque 7- 8 se crea. El tipo de grafico es etiqueta de texto. Este tipo de permite al usuario mover el gráfico de precios de un lado a otro, sin que ello afecte a las posiciones de los mensajes.

La función Inform() puede ser llamada desde cualquier lugar del programa en que se necesite mostrar un mensaje de texto. Como resultado de un periodo largo de funcionamiento, los mensajes se acumularan en la ventana. El usuario puede ver el historial de los mensajes cuando se aumenta el tamaño de la subventana donde está el indicador. Opcionalmente se puede fijar el tamaño de la ventana para ver las líneas de texto que se necesiten ( se recomienda de 3 a 4 líneas).

Fig. 156. Symbol window. Message in the indicator Subwindow.

Es fácil ver que se puede agregar nuevos tipos de mensajes para mostrar. Solo con agregar un nuevo caso o “case” en el operador “switch” en el bloque 7-8.
Función para el seguimiento de eventos
Muchos eventos ocurren cuando se está operando. Un operador puede ver algunos de ellos directamente en la grafica, por ejemplo, cuando cambia el precio o cuando se cruzan unas líneas de un indicador. Otros eventos, aunque son importantes para el operador, no se ven explícitamente en la grafica. Una gran parte de esos eventos se pueden detectar usando MQL4. 

Por ejemplo, el bróker puede cambiar las condiciones comerciales poco antes de que se publique una noticia fundamental o cuando el mercado está muy activo.  En tales casos, la extensión o la distancia permitida mínima para colocar una orden y para los StopLoss puede aumentarse. Si sucede esto, es necesario, primero detectar las nuevas condiciones y tenerlas en consideración, y en segundo caso, informar al operador sobre estos cambios. 

Para solucionar este problema, usted puede utilizar la siguiente función que maneja este tipo de eventos en su asesor experto o EA. 
Función definida por el usuario Events()
int Events()
Esta función calcula los cambios en la distancia mínima necesaria para crear una orden y para su StopLoss, así como los cambios en la lista (array) de las órdenes abiertas y ordenes pendientes que tiene la cuenta. Para utilizar esta función, se debe utilizar la función Terminal() que vimos anteriormente en otro programa. Esta función utiliza las siguientes arrays globales. 
· Mas_Ord_New - Array que lleva toda la información de las posiciones abiertas y órdenes pendientes. Este array contiene toda la información de cada posición, actualizada desde la última vez de la ejecución de la función Terminal(); 

· Mas_Ord_Old. - Array idéntico al anterior con la salvedad de que va a guardar la información desde la penúltima vez que se ha ejecutado la función Terminal(). 
También se utiliza las siguientes variables globales. 
- Level_new - el valor actual de la distancia mínima; 
- Level_old - el valor anterior de la distancia mínima.

Para mostrar los mensajes, la función utilizará a la función de datos Inform(). Si la función Inform() no se incluye en el Asesor de expertos, los mensajes no se verán.

La función que maneja los eventos la vamos a colocar en un archivo externo Events.mqh y luego la incluiremos en nuestro proyecto.
//--------------------------------------------------------------------------------
// Events.mqh
// Este código solo debe ser usado de manera educacional. 
//--------------------------------------------------------------------------- 1 --
// Función para seguir eventos. 
// Variables globales:
// Level_new            El ultimo valor de la distancia mínima 
// Level_old            El penúltimo valor de la distancia mínima 
// Mas_Ord_New[31][9]   Array con el listado de las ultimas ordenes 
// Mas_Ord_Old[31][9]   Array con el listado de las penúltimas ordenes 
//--------------------------------------------------------------------------- 2 --
int Events()                              // Función definida por el usuario 
  {
   bool Conc_Nom_Ord;                     // Coincidencia de las ordenes ..
   //.. en las arrays que llevan las ordenes 
//--------------------------------------------------------------------------- 3 --
   Level_new=MarketInfo(Symbol(),MODE_STOPLEVEL );// Ultima distancia conocida 
   if (Level_old!=Level_new)              // Si el ultimo no es igual al penúltimo..
     {                                    // Significa que han cambiado las condicione 
      Level_old=Level_new;                // Antiguo valor es ahora en nuevo valor
      Inform(10,Level_new);               // Se envía un mensaje con el informe 
     }
//--------------------------------------------------------------------------- 4 --
   // Busca ordenes perdidas, cambio den el tipo de orden, partes cerradas y ordenes reabiertas 
   for(int old=1;old<=Mas_Ord_Old[0][0];old++)// En el array de las penúltimas ordenes 
     {                                    // Suponiendo que..
      Conc_Nom_Ord=false;                 // .. las ordenes no coinciden 
      //--------------------------------------------------------------------- 5 --
      for(int new=1;new<=Mas_Ord_New[0][0];new++)//Ciclo en el array de las ..
        {                                 //..ultimas ordenes 
         //------------------------------------------------------------------ 6 --
         if (Mas_Ord_Old[old][4]==Mas_Ord_New[new][4])// Si coinciden en el numero 
           {                              // El tipo de la orden se convierte en..
            if (Mas_Ord_New[new][6]!=Mas_Ord_Old[old][6])//.. diferente
               Inform(7,Mas_Ord_New[new][4]);// Mensaje: modificación:)
            Conc_Nom_Ord=true;            // Las arrays de ordenes coinciden, ..
            break;                        // .. Se sale del ciclo actual. 
           }                              
         //------------------------------------------------------------------ 7 --
                                          // El numero de la orden no coincide
         if (Mas_Ord_Old[old][7]>0 &&     // coincide el numero magico
            Mas_Ord_Old[old][7]==Mas_Ord_New[new][7])//.. con el antiguo
           {               //significa que se a reabierto o se a cerrado parcialmente
                                             // Si los volúmenes coinciden,.. 
            if (Mas_Ord_Old[old][5]==Mas_Ord_New[new][5])
               Inform(8,Mas_Ord_Old[old][4]);// ..es que se ha reabierto
            else                             // En caso contrario.. 
               Inform(9,Mas_Ord_Old[old][4]);// .. se ha cerrado parcialmente
            Conc_Nom_Ord=true;               // Las arrays de ordenes coinciden, ..
            break;                           // .. Se sale del ciclo actual
           }                                 
        }
      //--------------------------------------------------------------------- 8 --
      if (Conc_Nom_Ord==false)               // Si estamos aquí,..
        {                                    // .. Esto significa que no encontró orden:(
         if (Mas_Ord_Old[old][6]==0)
            Inform(1, Mas_Ord_Old[old][4]);  // Orden de compra cerrada
         if (Mas_Ord_Old[old][6]==1)
            Inform(2, Mas_Ord_Old[old][4]);  // Orden de venta cerrada
         if (Mas_Ord_Old[old][6]> 1)
            Inform(3, Mas_Ord_Old[old][4]);  // Orden pendiente eliminada
        }
     }
//--------------------------------------------------------------------------- 9 --
   // Search for new orders
   for(new=1; new<=Mas_Ord_New[0][0]; new++)// En el array de ultimas ordenes
     {
      if (Mas_Ord_New[new][8]>0)            //Esto no es nuevo pero se ha reabierto
         continue;                          //..o parcialmente cerrado
      Conc_Nom_Ord=false;                   // Las arrays de ordenes no coinciden
      for(old=1; old<=Mas_Ord_Old[0][0]; old++)// Buscando las ordenes en 
        {                                   // .. el array de las penúltimas ordenes
         if (Mas_Ord_New[new][4]==Mas_Ord_Old[old][4])// Numero coincide.. 
           {                                          //.. de la orden
            Conc_Nom_Ord=true;              // La orden es encontrada, ..
            break;                          // .. Se sale del ciclo actual.
           }                                 
        }
      if (Conc_Nom_Ord==false)              // Si no se encuentra coincidencia... 
        {                                   // .. la orden es nueva :)
         if (Mas_Ord_New[new][6]==0)
            Inform(4, Mas_Ord_New[new][4]); // Orden de compra abierta 
         if (Mas_Ord_New[new][6]==1)
            Inform(5, Mas_Ord_New[new][4]); // Orden de venta abierta 
         if (Mas_Ord_New[new][6]> 1)
            Inform(6, Mas_Ord_New[new][4]); // Orden pendiente colocada 
        }
     }
//-------------------------------------------------------------------------- 10 --
   return;
  }
//-------------------------------------------------------------------------- 11 --
Las arrays y variables globales que se utilizaran, son explicadas en el bloque 1 – 2. En el bloque 2 – 3 se declara la variable Conc_Nom_Ord que se usara más adelante para analizar las órdenes. 

La función realiza un seguimiento a los cambios de la distancia mínima para colocar ordenes y StopLoss. Para ello, el valor actual de la distancia mínima Level_new se calcula en cada ejecución de la función (bloque 3 – 4) y, a continuación se compara con el valor anterior que está en Level_old (obtenido durante la anterior ejecución del a función). Si los valores de estas variables no son iguales, significa que la distancia mínima ha sido cambiada por el broker, un poco antes que se ejecutara la función. En este caso, el valor actual de la distancia mínima se asigna a la variable Level_old(se utilizara este valor en la próxima vez que se ejecute la función) y la función Inform() se ejecuta para mostrar el mensaje correspondiente. 

En general, se puede utilizar un método similar a este para detectar otros eventos, por ejemplo, cambios en el spread, el cambio de permisos para negociar una divisa (identificador MODE_TRADEALLOWED en la función MarketInfo()),  el fin de una nueva barra (véase el problema 27 LINK), el cruce de dos líneas de un indicador (véase fig .107 LINK), el llevar a cierta hora, etc. El programa puede detectar algunos eventos utilizando algunos valores del EA para informar al usuario de esto. 

En el bloque 4 – 10 se analiza las órdenes y ordenes pendientes. Se informa al usuario de la mayoría de cambios en una orden. Este análisis se realiza en dos etapas. En la primera fase, el programa detecta cambios como la eliminación y el cierre, cambio de tipo de orden y cerrar cierta parte de una orden o reabrir una orden. En la segunda fase (bloque 9 – 10) se buscan las nuevas órdenes. 

En los bloques 4 – 9 se analizan las órdenes que están en el array Mas_Ord_Old. La cantidad de iteraciones en el ciclo externo “for” depende de la cantidad total de ordenes en el array (elemento Mas_Ord_Old[0][0]) . Para saber si una orden no ha sufrido cambios, es necesario encontrar una orden igual en el array Mas_Ord_New. Esta búsqueda se realiza en el ciclo interno “for” (bloque 6-8), cuya cantidad de iteraciones es igual a la cantidad de ordenes en el array (elemento Mas_Ord_New[0][0]). Más adelante llamaremos a la array Mas_Ord_New “array nueva” y ha Mas_Ord_Old “array vieja”.

En los bloques 6 – 8, el programa busca ordenes, cuyas características sean diferentes. Por ejemplo, en el bloque 6 – 7, se verifica el número de la orden (véase la correspondencia de los índices del array con las características de la orden en la tabla 4 LINK). Si el número de una orden en la array vieja coincide con el número de una orden de la array nueva, significa que por lo menos, esta orden no ha sido cerrada o suprimida. Es necesario también verificar si el tipo de la orden no ha sido cambiado. Si ha sido cambiado, significa que una orden pendiente se ha convertido en una orden abierta.  En este caso, el mensaje correspondiente se a mostrado usando la función Inform(). Independientemente de que se haya cambiado (o se mantenga sin cambios) el tipo de orden, esta orden no será analizada más: el programa sale del ciclo interno y por último, comienza una iteración nueva del ciclo externo. 

Si en el bloque 6 -7 el programa ve que el numero de una orden en la array vieja no coincide con ninguno de los números de ordenes de la array nueva, el programa salta al bloque 7 - 8. Aquí el programa revisa si el número mágico de la orden actual de la array nueva es diferente a cero (todas las ordenes abiertas y pendientes hechas por este EA tienen un numero mágico distinto a cero). Si tiene un número mágico y este coincide con el número mágico de una orden en el array viejo, significa que esta orden esta activa, pero ha cambiado de alguna forma. Hay dos situaciones posibles en que el número de la orden puede haber cambiado. 

Situación 1. Una parte de la orden se ha cerrado. Se puede cerrar una parte de una orden (no pendiente!) en dos etapas según la tecnología aceptada en MT 4. En la primera etapa, la orden inicial es totalmente cerrada. Al mismo tiempo, una orden nueva con un volumen más pequeño se abre al mismo precio y con los mismos precios de StopLoss de la orden inicial. Esta nueva orden tiene un nombre único, distinto al número de la orden inicial. 

Situación 2. La orden ha sido reabierta por el bróker. Algunos bróker (debido a sus normas internas de contabilidad) cierran a la fuerza todas las ordenes al final del día e inmediatamente abren ordenes iguales, pero en el pago corriente y menos intercambio. but at the current price and minus swap. Este evento no afecta para nada los resultados económicos de una cuenta. Cada orden abierta no coincidirá con los números de las órdenes cerradas. 

Las dos situaciones se diferencian en el volumen de las nuevas órdenes: los volúmenes son diferentes en la primera y no cambian en la segunda. Esta diferencia en el volumen se utiliza en el bloque 7 – 8  para distinguir la razón por la que se ha modificado la orden. En ambos casos se mostrara el mensaje correspondiente (“la orden se ha cerrado en parte” o “la orden ha sido reabierta”).  

Si el programa no ha detectado coincidencias (bloque 6 – 7) o parecidos (bloque 7 – 8) en la array nueva, que cierren el ciclo interno, significa que la orden que está en la array vieja ha sido cerrada o eliminada. En este caso, el programa salta al bloque 8 – 9, donde se mostrara un mensaje de acuerdo con el tipo de orden. En el ejemplo anterior, se mostraran tres tipos de mensajes: para una orden de compra, para una orden de venta y para una orden pendiente de cualquier tipo. Si se desea, esta parte puede cambiarse o mejorarse, colocando un mensaje para los diferentes tipos de orden pendientes. 

En la segunda parte del programa (bloque 9 – 10), se analizan las nuevas órdenes en el array nuevo. Esto se hace para detectar órdenes abiertas y pendientes. En el ciclo externo “for”, se revisan las características de todas las órdenes que están en la array nueva. Para identificar las órdenes reabiertas y las cerradas en parte, el programa utiliza una simple característica – la existencia del comentario. Cuando se cierra en parte una orden o se reabre, el servidor del bróker agrega un comentario a la orden donde coloca el número de la orden original. Como en este EA no se agregan comentarios a las órdenes, la existencia de un comentario en una orden indica que la orden no es nueva. 

Si una orden no tiene comentario, el programa busca una orden con el mismo número en la array vieja. Si el programa encuentra un numero de orden que este tanto en la array vieja como en la nueva en el ciclo “for” significa que la orden no es nueva. Pero si encuentra un número en la array nueva que no está en la array vieja, significa que se ha abierto una nueva orden o una nueva orden pendiente. En la parte inferior del bloque 9 – 10 se ejecuta la función Inform() para que muestre el tipo de orden que se ha creado. 

El uso de la función Events() resulta ser muy útil en la práctica. Después que el programador utilice esta función en un EA, se acostumbrara a utilizarla en sus demás proyectos. Debe observase que las funciones Evenys() y Terminal() están estrechamente relacionadas. Si se desea realizar cambios en estas dos funciones (por ejemplo cambiar los nombres de las variables globales), se deberá hacer los cambios en las dos funciones. Si a causa de la estrategia, se necesita colocar comentarios a las órdenes, la parte de este EA que utiliza los comentarios deberá ser adaptada según sea el caso (bloque 9 – 10).

La cantidad de eventos que maneja la función Events() puede aumentarse sustancialmente. Por ejemplo, si se desea mostrar todos los eventos relacionados con las órdenes, se debe analizar las características de las órdenes, como los cambios en el StopLoss de las órdenes abiertas o pendientes o la forma en que se ha cerrado una orden (si la orden se ha cerrado oponiéndola contra otra orden contraria, o se ha cerrado individualmente) y la razón del cierre de una operación o eliminación de una orden pendiente (Si el precio toco un StopLoss, o se ha cerrado manualmente por el operador, etc…). 
Función que calcula el volumen de las órdenes
En la operación real, un operador necesita calcular la cantidad de lotes con los que va abrir una posición. Es muy difícil crear una función universal que cumpla este fin, pues cada estrategia puede utilizar una forma diferente de calcular la cantidad de lotes en una posición. Por ejemplo, algunas estrategias requieren que solo exista una sola orden abierta a la vez, mientras que otras no tienen restricciones en la cantidad de ordenes abiertas al mismo tiempo. También existen estrategias basadas en tener varias órdenes pendientes al mismo tiempo. 

Uno de los métodos más comunes para calcular el volumen de una orden (para estrategias que solo permiten una orden a la vez) es el método de inversiones progresivas. Según este método, el costo de cada orden es proporcional al margen libre disponible en el momento de crear la orden. Si una orden se cierra con beneficio, la cantidad permitida de lotes para una nueva orden aumenta. Y si cierra con pérdida, esta cantidad disminuye. 

En el siguiente ejemplo, vamos a crear una función llamada Lot() que nos permitirá calcular el número de lotes para una orden nueva, y que nos dará dos opciones.

Opción 1. El usuario establece manualmente la cantidad de lotes para las órdenes. 

Opción 2. La cantidad de lotes se calcula de acuerdo con la cantidad de dinero asignado por el usuario. Esta cantidad de dinero asignado se calcula sobre el porcentaje de margen libre.  
Función definida por el usuario Lot()
bool Lot()
Esta función calcula la cantidad de lotes para las nuevas órdenes.  Como resultado de la ejecución de esta función, el valor de la variable global Lots_New cambia, esta variable representa el número de lotes para una orden en el programa. La función devuelve TRUE, si el margen libre es suficiente para abrir una orden con la cantidad mínima de lotes posibles (en la divisa donde se agrega el EA). De lo contrario devuelve FALSE. 

Esta función utilizara las siguientes variables globales:
· Lots - volumen de lotes definidos por el usuario; 

· Percent - El porcentaje de margen libre definido por el usuario. 

Para mostrar los mensajes, la función utilizara la función Inform(). Si esta no está incluida los mensajes no se verán en pantalla. 

El siguiente es el código de la función Lot() al que guardaremos en un archivo llamado Lot.mqh y que luego incluiremos en nuestro proyecto. 
//----------------------------------------------------------------------------------
// Lot.mqh
// Este código solo debe ser usado de manera educacional.
//----------------------------------------------------------------------------- 1 --
// Función que calcula la cantidad de lotes.

// Variables globales utilizadas:

// double Lots_New - la cantidad de lotes para nuevas ordenes (calculado)

// double Lots - cantidad de lotes deseados definidos por el usuario.

// int Percent - porcentaje de margen libre definido por el usuario

// Valores devueltos:

// true - si hay dinero suficiente para el volumen mínimo permitido

// false - si no hay dinero suficiente para el volumen mínimo permitido
//----------------------------------------------------------------------------- 2 --
bool Lot()                                     // Función definida por el usuario 
  {
   string Symb   =Symbol();                    // Divisa
   double One_Lot=MarketInfo(Symb,MODE_MARGINREQUIRED);//!- Costo lote
   double Min_Lot=MarketInfo(Symb,MODE_MINLOT);// Cantidad mínima de lotes
   double Step   =MarketInfo(Symb,MODE_LOTSTEP);// Paso en el cambio de volumen
   double Free   =AccountFreeMargin();         // Margen libre
//----------------------------------------------------------------------------- 3 --
   if (Lots>0)                                 // El volumen es explícitamente fijado..
     {                                         // ..en la comprobación  
      double Money=Lots*One_Lot;               // Costo de orden
      if(Money<=AccountFreeMargin())           // Si el margen libre es suficiente..
         Lots_New=Lots;                        // .. se acepta la cantidad de lotes 
      else                                     // Si el margen libre no es suficiente..
         Lots_New=MathFloor(Free/One_Lot/Step)*Step;// Se calculan los lotes
     }
//----------------------------------------------------------------------------- 4 --
   else                                        // Si no está definido el volumen 
     {                                         // ..se toma el porcentaje 
      if (Percent > 100)                       // porcentaje pero incorrecto..
         Percent=100;                          // .. entonces no será mas de 100
      if (Percent==0)                          // Si se fija 0 ..
         Lots_New=Min_Lot;                     // .. entonces el loto será el mínimo
      else                                     // Cantidad de lotes deseados:
         Lots_New=MathFloor(Free*Percent/100/One_Lot/Step)*Step;// Calculo
     }
//----------------------------------------------------------------------------- 5 --
   if (Lots_New < Min_Lot)                     // Si es mejor a lo permitido..
      Lots_New=Min_Lot;                        // .. entonces será el mínimo
   if (Lots_New*One_Lot > AccountFreeMargin()) // No es suficiente aún....
     {                                         // .. para el lote mínimo:(
      Inform(11,0,Min_Lot);                    // Mensaje...
      return(false);                           // .. y se sale  
     }
   return(true);                               // salimos de la función 
  }
//----------------------------------------------------------------------------- 6 --
La función tiene un código simple. En el bloque 1-2, se describen las variables globales y los valores devueltos. En el bloque 2-3, los valores de algunas variables se calculan. Para hacer cálculos, se utiliza la siguiente prioridad como configuración: Si el usuario ha fijado una cantidad diferente a cero de lotes, el valor de porcentaje de margen libre no se toma en cuenta. Las variables globales externas que llevan los lotes y el porcentaje se declaran en el archivo Variables.mqh. 

En el bloque 3-4, se hacen cálculos para la situación, en que el usuario ha definido un valor diferente a cero en el volumen de lotes, en las variables globales externas. En este caso, el programa hace una comprobación. Si el margen libre es suficiente para abrir una nueva orden con la cantidad definida de lotes, entonces el valor establecido por el usuario va ser asignado a la variable global Lots_New que será utilizada en futuros cálculos. Si el margen libre no es suficiente, entonces la cantidad máxima posible de lotes se calcula para su uso futuro (véase funciones matemáticas LINK).   

Si el usuario ha definido cero en la cantidad de lotes, el programa salta al bloque 4 – 5. Al mismo tiempo, tomamos en cuenta el porcentaje de margen libre especificado por el usuario en la variable externa Percent. El programa hace una comprobación: si el valor supera cien (porcentaje),  el valor 100 se utilizara en los cálculos. Si el usuario ha definido cero en la variable Percent, la cantidad de lotes será equivalente al valor mínimo establecido por el bróker. Todos los valores intermedios (de 1 a 99) se utilizaran como porcentaje en el margen libre. 

En el bloque 5 – 6, se hacen las comprobaciones necesarias. Si la cantidad calculada de lotes resulta ser menor que el mínimo permitido (por ejemplo, el  valor cero puede obtenerse en el bloque 4-5, si el usuario ha definido un valor muy pequeño en la variable Percent), entonces el valor mínimo será asignado a la variable Lots_new. A continuación, el programa comprueba si hay suficiente dinero libre para abrir una orden con la cantidad de volumen previamente calculada de lotes (puede haber poco dinero en la cuenta). Si el dinero disponible no es suficiente, el programa muestra un mensaje al usuario, luego se sale de la función devolviendo “false”. Sin embargo,  si hay suficiente dinero la función devuelve true. 
Función que calcula la estrategia
El éxito de cualquier estrategia depende principalmente de los criterios que se tengan para operar. La función que define estos criterios en la mayoría de los casos es la más importante e imprescindible de todas. Según la estrategia, la función puede devolver valores que correspondan con unos criterios comerciales particulares. 

En la mayoría de los casos, se pueden definir los siguientes criterios:

•
Criterio para abrir una orden;

•
Criterio para cerrar una orden;

•
Criterio para cerrar una parte de una orden;

•
Criterio para cerrar ordenes opuestas;

•
Criterio para modificar el StopLoss de una orden;

•
Criterio para colocar una orden pendiente;

•
Criterio para cancelar una orden pendiente;

•
Criterio para modificar el precio de apertura de una orden pendiente;

•
Criterio para modificar el StopLoss de una orden pendiente;

En la mayoría de los casos, la activación de un criterio comercial es exclusiva en relación a otros criterios comerciales. In most cases, the triggering of one trading criterion is exclusive as related to other trading criteria. Por ejemplo, si el criterio para abrir una orden de compra se vuelve importante en un momento dado, esto significará que los criterios usados para cerrar órdenes de compra o abrir órdenes de venta, no pueden ser importantes en ese mismo momento (véase la relación de criterios comerciales LINK). Al mismo tiempo, según las normas inherentes de una estrategia dada, algunos criterios se pueden activar simultáneamente. Por ejemplo, los criterios para cerrar una orden de venta y los criterios para modificar una orden pendiente BuyStop, se pueden dar al mismo tiempo. 

Una estrategia comercial impone requisitos al contenido y a la tecnología que usa la función que define los criterios comerciales. Una función solo puede devolver un valor. Por lo tanto, si la estrategia comercial de un asesor experto implica utilizar criterios comerciales mutuamente excluyentes, el valor que devuelve la función puede estar asociado a uno de esos criterios. Sin embargo, si la estrategia permite activar varios criterios al mismo tiempo, sus valores deben ser enviados por medio de otras funciones para que sean procesados, utilizando las variables globales para ello. 

La estrategia comercial que veremos en el EA más abajo, solo permite la utilización de criterios mutuamente excluyentes. Por esta razón la función que utilizaremos para definir los criterios, llamada Criterion(), se comunicara con otras funciones, por medio del valor que esta devuelva . 
Función definida por el usuario Criterion()
int Criterion()
Esta función calcula los criterios comerciales. Puede devolver los siguientes valores:

10 - accionó un criterio comercial para abrir una orden de compra;

20 - accionó un criterio comercial para abrir una orden de venta;

11 - accionó un criterio comercial para cerrar una orden de compra;

21 - accionó un criterio comercial para cerrar una orden de venta;

0 – No hay criterios importantes disponibles;

-1 – la divisa usada no es EURUSD.

La función utiliza las siguientes variables externas:

St_min - el nivel inferior del oscilador estocástico;

St_max - el nivel superior del oscilador estocástico;

Open_Level - el nivel del indicador MACD (para abrir una orden);

Close_Level - el nivel del indicador MACD (para cerrar una orden).

Para mostrar los mensajes, la función utilizara la función Inform(). Si esta no está incluida los mensajes no se verán en pantalla. 

El siguiente es el código de la función Criterion() que definirá los criterios comerciales, la que guardaremos en un archivo llamado Criterion.mqh y que luego incluiremos en nuestro proyecto. 
//-------------------------------------------------------------------------
// Criterion.mqh
// Este código solo debe ser usado de manera educacional. 
//-------------------------------------------------------------------- 1 --
// Función que calcula los criterios comerciales. 
// Valores devueltos:

// 10 – Abriendo compra 

// 20 – Abriendo venta

// 11 – Cerrando compra

// 21 – Cerrando venta

// 0  - no hay criterio importante disponible

// -1 – se esta utilizando otra divisa
//-------------------------------------------------------------------- 2 --
// Variables externas:
extern int St_min=30;                  // Nivel mínimo de estocástico 
extern int St_max=70;                  // Nivel máximo de estocástico 
extern double Open_Level =5;           // MACD nivel para abrir orden (+/-)
extern double Close_Level=4;           // MACD nivel para cerrar orden (+/-)
//-------------------------------------------------------------------- 3 --
int Criterion()                        // Función definida por el usuario
  {
   string Sym="EURUSD";
   if (Sym!=Symbol())                  // Si la divisa es diferente a EURUSD
     {
      Inform(16);                      // Mensaje..
      return(-1);                      // .. y salida
     }
   double
   M_0, M_1,                           // Valor PRINCIPAL en vela 0 y 1
   S_0, S_1,                           // Value Valor SEÑAL en vela 0 y 1
   St_M_0, St_M_1,                     // Valor PRINCIPAL en vela 0 y 1
   St_S_0, St_S_1;                     // Valor SEÑAL en vela 0 y 1
   double Opn=Open_Level*Point;        // Apertura de nivel de MACD (pips)
   double Cls=Close_Level*Point;       // Cierre de nivel de MACD (pips)
//-------------------------------------------------------------------- 4 --
   // Parámetros de los indicadores técnicos:
   M_0=iMACD(Sym,PERIOD_H1,12,26,9,PRICE_CLOSE,MODE_MAIN,0); // 0 vela
   M_1=iMACD(Sym,PERIOD_H1,12,26,9,PRICE_CLOSE,MODE_MAIN,1); // 1 vela
   S_0=iMACD(Sym,PERIOD_H1,12,26,9,PRICE_CLOSE,MODE_SIGNAL,0);//0 vela
   S_1=iMACD(Sym,PERIOD_H1,12,26,9,PRICE_CLOSE,MODE_SIGNAL,1);//1 vela
 
   St_M_0=iStochastic(Sym,PERIOD_M15,5,3,3,MODE_SMA,0,MODE_MAIN,  0);
   St_M_1=iStochastic(Sym,PERIOD_M15,5,3,3,MODE_SMA,0,MODE_MAIN,  1);
   St_S_0=iStochastic(Sym,PERIOD_M15,5,3,3,MODE_SMA,0,MODE_SIGNAL,0);
   St_S_1=iStochastic(Sym,PERIOD_M15,5,3,3,MODE_SMA,0,MODE_SIGNAL,1);
//-------------------------------------------------------------------- 5 --
   // Calculando el criterio de operación
   if(M_0>S_0 && -M_0>Opn && St_M_0>St_S_0 && St_S_0<St_min)
      return(10);                      // Abriendo compra
   if(M_0<S_0 &&  M_0>Opn && St_M_0<St_S_0 && St_S_0>St_max)
      return(20);                      // Abriendo venta
   if(M_0<S_0 &&  M_0>Cls && St_M_0<St_S_0 && St_S_0>St_max)
      return(11);                      // Cerrando compra  
   if(M_0>S_0 && -M_0>Cls && St_M_0>St_S_0 && St_S_0>St_min)
      return(21);                      // Cerrando venta
//-------------------------------------------------------------------- 6 --
   return(0);                          // Salimos de la función definida por el usuario
  }
//-------------------------------------------------------------------- 7 --
En el bloque 1 – 2, se explica los valores devueltos por la función. En el bloque 2 – 3, se declaran algunas variables externas. El archivo incluido Criterion.mqh es el único archivo usado en este EA, en el cual (en este caso externa) se declaran variables globales. En la sección llamada estructura de un programa normal, se pueden encontrar razones para declarar todas las variables globales sin excepción en un archivo separado Variables.mqh. En este caso, las variables externas se declaran en el archivo Criterion.mqh por dos razones: primero, para demostrar que es técnicamente posible (no siempre es posible); y en segundo lugar para mostrar cómo utilizar variables externas en la depuración y las pruebas de un programa. 

Es técnicamente posible declarar variables externas en el archivo Criterion.mqh, porque estas variables no se utilizarán en otras funciones del programa. Los valores de las variables externas declaradas en el bloque 2-3 determinan los niveles para el oscilador estocástico y el indicador MACD y se utilizaran solamente en la función Criterion(). La declaración de variables externas en el archivo que contiene la función que define los criterios comerciales puede ser razonable, si el archivo se utiliza temporalmente para la depuración y cálculo de los valores de esas variables en el programa. Con este fin, se puede agregar otras variables externas en el programa, por ejemplo, para optimizar las entradas del indicador (en este caso, las constantes fijadas en los valores 12,26,9 para MACD y 5,3,3 para el oscilador estocástico).  Una vez hechas las optimizaciones de las variables, usted puede suprimir estas variables externas del programa y sustituirlas por constantes con los valores calculados en la optimización. 

En el bloque 3-4, se abren y describen las variables locales. El EA está pensado para que sea utilizado en la divisa “EURUSD”, así que en el bloque 3 – 4 se revisa si esta condición se cumple. Si el EA se pone en marcha en otra divisa, la función termina su ejecución y devuelve el valor -1 (divisa incorrecta).  

En el programa, los valores de dos indicadores se calculan en la vela actual y en la anterior (bloque 4-5). Generalmente, cuando se utiliza el oscilador estocástico y MACD, las señales para comprar o vender se dan cuando dos líneas del indicador se encuentran entre sí.  En este caso, utilizamos dos indicadores simultáneamente para definir los criterios comerciales. La probabilidad de que se crucen simultáneamente líneas de dos indicadores es algo baja. Es mucho más probable que se crucen una por una – primero en un indicador, y un rato más adelante en otro. Si las líneas de estos dos indicadores se cruzan dentro de un corto periodo de tiempo,  se considera que se ha formado un criterio comercial. 

Por ejemplo, a continuación se muestra cómo se calcula un criterio comercial para hacer una compra (bloque 5-6):
if(M_0>S_0 && -M_0>Opn && St_M_0>St_S_0 && St_S_0<St_min)
Según el código anterior, el criterio para abrir una orden de compra se forma cuando se cumplen las siguientes condiciones:
· En el indicador MACD, la línea PRINCIPAL (histograma) del indicador está por encima de la línea SEÑAL del indicador y debajo del nivel más bajo Open_Level (Fig. 157); 

· En el Oscilador Estocástico, la línea PRINCIPAL  (histograma) está por encima de la línea SEÑAL del indicador y debajo del nivel más bajo St_min (Fig.158). 

Fig. 157. Condiciones necesarias de las líneas del indicador MACD para confirmar la importancia de los criterios para abrir y cerrar órdenes. 
En la parte izquierda de la fig. 157, se muestran las posiciones de las líneas del indicador MACD, en las cuales dos criterios se accionan – abrir orden de compra y cerrar orden de venta. La línea PRINCIPAL del indicador esta debajo del nivel 0.0005 en el transcurso de T1 = t 1 - t 0. Si el oscilador estocástico también da una señal de entrada en este momento, se activara el criterio para abrir una orden de compra. En él transcurso de T2 = t 2 - t 0, la línea PRINCIPAL está debajo del nivel 0.0004.  Si el oscilador estocástico también da una señal de salida en este momento, se activara el criterio para cerrar una orden de venta. 

Observe por favor que, en T1 se activan dos criterios (si son confirmados por el oscilador estocástico). Antes habíamos mencionado que la función Criterion() devuelve un solo valor, a saber, el valor que se asigna al criterio activado. Durante este periodo, hay que elegir uno de los dos criterios. Este problema se debe solucionar por adelantado en el programa, según las reglas de la estrategia comercial. 

En este caso (según la estrategia comercial considerada), la prioridad de abrir una orden de compra es mayor que la de cerrar una orden de venta.  Es por esta razón que en el bloque 5 – 6, la línea de código que contiene la orden de compra se coloca por encima de las demás líneas de código. Si durante el período de T1 (fig. 157), tenemos la confirmación del oscilador estocástico, la función devolvería 10, que representa el criterio de compra. Luego dentro del periodo T1 a t2, la función devolverá 21, asignado al criterio para cerrar una venta. 

Al  mismo tiempo, en la función que maneja las peticiones comerciales, se formará una petición comercial. En primer lugar se accionara el criterio para abrir una orden de compra, en segundo, se accionara el criterio para cerrar todas las órdenes de venta. Tan pronto como no haya ordenes, se solicitara una orden de compra. Respectivamente, cuando el criterio para cerrar las órdenes de venta se accione, se ejecutara una secuencia que cerrará todas las órdenes de venta abiertas. (ver  función de comercio LINK).

Las condiciones en que el Oscilador Estocástico da confirmación se muestra en la figura 158.

Fig. 158. Condiciones necesarias de las líneas del Oscilador Estocástico para confirmar la importancia de los criterios para abrir y cerrar órdenes.

Según el código de programa escrito en el bloque 5-6, los criterios para abrir una compra y cerrar una venta se activaran, siempre que la línea PRINCIPAL del indicador, está por encima de la línea SEÑAL en el Oscilador Estocástico, la línea PRINCIPAL está por debajo del nivel mínimo St_min. En la fig. 158, estas condiciones se dan en el periodo TS. Los criterios inversos se dan en el segundo Ts, donde se forman los criterios comerciales para abrir una orden de venta y cerrar una orden de compra. 

Es importante señalar que en esta estrategia, el indicador MACD esta funcionando en graficas de 1 hora, mientras que el oscilador estocástico funciona en graficas de 15 minutos. El tiempo de las graficas se puede cambiar mientras se está optimizando y perfeccionando la estrategia. Sin embargo, después de hacer estas pruebas, y tener los valores optimizados en la función Criterion(), es necesario convertir estos valores en constantes para todos los parámetros calculados incluyendo el tiempo de las graficas. El EA debe ser utilizado bajo las condiciones en las que se ha creado. En el ejemplo anterior (con los valores de los periodos PERIOD_H1 y PERIOD_M15 especificados explícitamente en los indicadores), el EA tomara las mismas decisiones independientemente del periodo del grafico actual de la divisa donde está funcionando el EA. 

	Los criterios comerciales utilizados en este EA están hechos para propósitos de enseñanza y no deben ser utilizados en cuentas reales.


Funciones que ejecutan la estrategia 
En general, un asesor de expertos normal tiene una serie de funciones que se encargan de calcular la estrategia, abrir, cerrar, modificar y eliminar órdenes. Estas funciones pueden ser divididas en dos categorías – funciones de control y funciones ejecutivas. En la mayoría de los casos, en un EA se utiliza solamente una función de control y varias funciones ejecutivas.

Una estrategia de un EA normal, se basa en dos funciones – una función que define los criterios comerciales y una función que controla las operaciones. No debe haber ningún indicador de estrategias en alguna otra parte del programa. La función que controla las operaciones y la función que define los criterios comerciales deben coordinarse mutuamente en los parámetros que se pasan. 

Cada función ejecutiva que controla las operaciones tiene una serie de tareas. De acuerdo con los requisitos de la estrategia comercial, las funciones comerciales se pueden utilizar para cumplir las siguientes funciones en un EA:

· Apertura de una orden de cualquier tipo; 

· Cierre de una orden de cualquier tipo; 

· Cierre parcial de una orden de cualquier tipo; 

· Cierre de todas las ordenes de cualquier tipo; 

· Cierre de dos órdenes contrarias de cualquier volumen

· Cierre de todas las ordenes

· Modificación de los precios de stop de cualquier tipo de orden

· Colocaciones de ordenes pendientes de cualquier tipo 

· Eliminación de ordenes pendientes de cualquier tipo 

· Eliminación de todas las ordenes pendientes de cualquier tipo 

· Eliminación de todas las ordenes pendientes 

· Modificación de ordenes pendientes de cualquier tipo
La secuencia de pasos que sigue un asesor experto normal, generalmente es la siguiente: Las funciones ejecutivas, reciben un valor devuelto por la función que calcula la estrategia y lleva los criterios comerciales, y según este valor las funciones ejecutivas realizan una operación en el servidor del broker. 
Función definida por el usuario Trade()
int Trade( int Trad_Oper )
Esta función ejecuta la estrategia. 

El parámetro Trad_Oper debe recibir alguno de los siguientes valores, que representan un tipo de operación a ejecutar. 

10 - Criterio comercial para abrir una orden de compra;

20 - Criterio comercial para abrir una orden de venta;

11 - Criterio comercial para cerrar una orden de compra;

21 - Criterio comercial para cerrar una orden de venta;

0 – No hay criterios importantes disponibles;

-1 – la divisa usada no es EURUSD.

Para que esta función pueda ejecutarse, necesita utilizar las siguientes funciones:
· Función Close_All () – Se encarga de cerrar órdenes;

· Función Open_Ord () - Se encarga de abrir órdenes;

· Función Tral_Stop () - Se encarga de modificar órdenes;
· Función Lot() – Calcula la cantidad de lotes para una nueva orden.
El siguiente es el código de la función Trade() que ejecutara la estrategia, y que guardaremos en un archivo llamado Trade.mqh y que luego incluiremos en nuestro proyecto: 
//------------------------------------------------------------------------
// Trade.mqh
// Este código solo debe ser usado de manera educacional. 
//------------------------------------------------------------------------
// Funcion Trade.
//------------------------------------------------------------------- 1 --
int Trade(int Trad_Oper)              // Función definida por el usuario 
  {
// Trad_Oper – parámetro con el tipo de operación:

// 10 – Abrir compra

// 20 - Abrir Sell

// 11 - Cerrar compra

// 21 - Cerrar Sell

// 0 - no hay criterio importante disponible

// -1 - se está utilizando otra divisa
   switch(Trad_Oper)
     {
      //------------------------------------------------------------- 2 --
      case 10:                         // Criterio para = compra
         Close_All(1);                 // Cerrar todas las ventas
         if (Lot()==false)             // No hay suficiente dinero para el lote mínimo.
            return;                    // Salir de función
         Open_Ord(0);                  // Abrir compra
         return;                       // Hecha la operación se sale
         //---------------------------------------------------------- 3 --
      case 11:                         // Criterio para = cerrar compra
         Close_All(0);                 // Cerrar todas las compras
         return;                       // Hecha la operación se sale
         //---------------------------------------------------------- 4 --
      case 20:                         // Criterio para = vender
         Close_All(0);                 // Cerrar todas las compras
         if (Lot()==false)
            return;                    // Salir de función
         Open_Ord(1);                  // Abrir venta
         return;                       // Hecha la operación se sale
         //---------------------------------------------------------- 5 --
      case 21:                         // Criterio para = Cerrar ventas
         Close_All(1);                 // Cerrar todas las ventas
         return;                       // echa la operación se sale
         //---------------------------------------------------------- 6 --
      case 0:                          // Se conservas las posiciones abiertas
         Tral_Stop(0);                 // Mueve el stop de compra
         Tral_Stop(1);                 // Mueve el stop de venta
         return;                       // Hecha la operación se sale
         //---------------------------------------------------------- 7 --
     }
  }
//------------------------------------------------------------------- 8 --
La función Trade() es llamada en la función especial start()en el asesor experto usualexpert.mq4. Esta función recibe por parámetro el valor devuelto por la función Criterion();

En el bloque 1-2 se describen los criterios comerciales considerados en la estrategia. En esta función utilizamos el operador switch() (bloque 2-7) que nos permite seleccionar un grupo de funciones ejecutivas según el criterio comercial recibido. Según la estrategia comercial, el EA abre y cierra órdenes. Este EA no utiliza órdenes pendientes, así que no se utilizaran funciones que manejen órdenes pendientes.  
En la sección llamada “Función que calcula la estrategia” LINK, dijimos que algunos criterios comerciales pueden solicitar varias órdenes. Así, en caso de activarse el criterio para comprar (el valor del parámetro Trad_Oper es igual a 10), el ejecuta el código que está en el “case 10” del operador switch() en el bloque 2 – 3). En este caso el programa llama primero a la función Close_All (1). La ejecución da como resultado el cierre de todas las órdenes de venta en la divisa “EURUSD”. Una vez han sido cerradas todas las órdenes de venta, se comprueba si ha quedado suficiente dinero para la siguiente orden. Para saber eso, se llama a la función Lot() (véase la función que calcula los lotes LINK). Si esta función devuelve “false”, significa que no hay suficiente dinero para utilizar el mínimo de lotes. Si es así, la función Trade() termina su ejecución.  Si hay el dinero suficiente, se ejecuta la función Open_Ord (0) para que abra una orden de compra con la cantidad de lotes calculados en la función Lot(). Estos pasos descritos, representa la respuesta del asesor experto a la situación del mercado (de acuerdo con los criterios comerciales seleccionados). 
Si el criterio comercial indica que se deben cerrar las compras, el programa saltara al “case 11” en el bloque 3 – 4. En este caso solo se llama a la función Close_All (0), y esta cerrara todas las órdenes de compra abiertas. Los bloques 4-6 son parecidos a los bloques 2-4, el programa salta a los “case 20” y “case 21” si se activan los criterios para abrir órdenes de venta o para cerrar ventas. 
Hay que tener en cuenta que todas las funciones ejecutivas que abren o cierran operaciones se ejecutan en la función Trader(), y que esta función a su vez, es ejecutada en la función especial start() del EA, que a su vez, se ejecuta cada vez que se recibe un nuevo tick. El código de la función Trade() está escrito de tal forma, que el control no se devuelve a la función start() (y por ende al terminal del cliente) hasta que todas las funciones comerciales se hayan ejecutado por completo. Esta es la razón por la cual todas las operaciones previstas en el EA para cada criterio comercial son hechas una por una sin cortes. La única excepción pueden ser los casos de errores críticos durante las operaciones comerciales (véase la función que procesa los errores LINK).
Si no se activa un criterio comercial, (el parámetro Trad_Oper es igual a 0) en la ejecución de la función Criterion(), el programa salta al “case 0”, que llama dos veces a la función Tral_Stop() para que modifique los valores de stop de diferentes ordenes de mercado. La estrategia comercial de este EA en particular, permite que solo haya una orden de mercado a la vez, por este motivo, no importa el orden de ejecución de las funciones Tral_Stop (0) y Tral_Stop (1). En este caso se escogió un orden aleatorio. 

Si la función Criterion() devuelve -1, esto significa que el EA está operando en una grafica diferente a EURUSD. En este caso la función Trade() no llamará a ninguna función ejecutiva y devolverá el control a la función especial start().
Función definida por el usuario Close_All()
int Close_All( int Tip)
Esta función cierra todas las órdenes de mercado de un tipo según el parámetro Tip.
El parámetro TIP debe recibir los siguientes valores que representaran el tipo de órdenes a cerrar. 

0 - Cierre de compras;

1 - Cierre de ventas.

Para ejecutar esta función, es necesario utilizar varias funciones que ya hemos visto, como la función que lleva las ordenes Terminal(), la que maneja los eventos Events() y la que procesa los errores Errors(). También para mostrar los mensajes en pantalla utilizaremos la función Inform(). Si la función Inform() no se incluye en el EA, no aparecerá ningún mensaje .

Las siguientes variables globales se utilizarán.
· Mas_Ord_New - El array con las características de las órdenes abiertas desde la última ejecución de la función Terminal(); 

· Mas_Tip - El array que lleva el listado de los diferentes tipos de órdenes abiertas y la cantidad de cada tipo de orden desde la última ejecución de la función Terminal(). 

La función ejecutiva Close_All () se guardara en el archivo Close_All.mqh:
//---------------------------------------------------------------------------------
// Close_All.mqh
// Este código solo debe ser usado de manera educacional.
//---------------------------------------------------------------------------- 1 --
// Función que cierra todas las ordenes de un solo tipo

// Variables globales:

// Mas_Ord_New array con listado de ordenes

// Mas_Tip Order array con la cantidad de tipos de ordenes
//---------------------------------------------------------------------------- 2 --
int Close_All(int Tip)                    // Función definida por el usuario 
  {
   // int Tip                             // Tipo de orden 
   int Ticket=0;                          // Numero de orden
   double Lot=0;                          // Numero de lotes de una orden 
   double Price_Cls;                      // Precio de cierre
//---------------------------------------------------------------------------- 3 --
   while(Mas_Tip[Tip]>0)                 // Mientras haya ordenes abiertas..
     {                                   //.. de un tipo
      for(int i=1; i<=Mas_Ord_New[0][0]; i++)// Clico en las ordenes abiertas
        {
         if(Mas_Ord_New[i][6]==Tip &&     // Entre las ordenes de un tipo…
            Mas_Ord_New[i][5]>Lot)        // .. seleccione el más costoso 
           {                              // Éste se encontró en antes. 
            Lot=Mas_Ord_New[i][5];        // la cantidad más grande de lotes encontrados 
            Ticket=Mas_Ord_New[i][4];     // El código de la orden 
           }
        }
      if (Tip==0) Price_Cls=Bid;          // Para las órdenes de compra
      if (Tip==1) Price_Cls=Ask;          // Para las órdenes de venta
      Inform(12,Ticket);                  // Mensaje sobre que se va ser un intento de cierre
      bool Ans=OrderClose(Ticket,Lot,Price_Cls,2);// Orden de cierre!:)
      //---------------------------------------------------------------------- 4 --
      if (Ans==false)                     // Si se fallo :( 
        {                                // Revisar el error:
         if(Errors(GetLastError())==false)// Si el error es crítico,
            return;                       // .. se sale.
        }
      //---------------------------------------------------------------------- 5 --
      Terminal();                         // Orden para llevar la contabilidad
      Events();                           // eguimiento de eventos
     }
   return;                                // Sale de la función definida por el usuario
  }
//---------------------------------------------------------------------------- 6 --
En el bloque 1-2, se describen las variables globales usadas. En el bloque 2-3, se declaran y describen las variables abiertas. La condición Mas_Tip[Tip]>0  en la cabecera del ciclo “while” (los bloques 3-6) implica que este ciclo terminara hasta que se cierren todas las ordenes del tipo pedido. El elemento de la array global Mas_Tip [Tip] contiene la cantidad de órdenes del tipo correspondiente. Por ejemplo, si la función Close_All () se llama con el parámetro 1, significa que la función debe cerrar todas las órdenes de venta. (véase los tipos de comercio LINK). En este caso, el elemento del array Mas_Tip [1] contendrá la cantidad de órdenes de venta abiertas (dato conocido desde la última ejecución de la función Terminal()). De esta manera, el ciclo “while” se ejecutara tantas veces haya ordenes de ventas abiertas. 

Si el operador no interviene en las operaciones del EA (es decir, él o ella no ponen ordenes manualmente), entonces solo debería haber una orden abierta sea de un tipo o de otro. Sin embargo, si el operador ha agregado una o varias órdenes manualmente, entonces la función Close_All() deberá seguir una serie de pasos para manejar esta posibilidad. La secuencia preferible es cerrar las ordenes mas grandes primero. Por ejemplo, si  hay tres órdenes de venta cuando se ejecuta la función Close_All (), una de ellas de 5 lotes, otra de 1 lote, y la tercera de 4 lotes, estas órdenes serán cerradas en la secuencia siguiente según el razonamiento anterior: la primera orden en cerrarse será la de 5 lotes, luego la de 4 y por último la de 1 lote. 

Observe por favor que la cantidad de lotes es el único criterio usado para determinar el orden de cierre. El beneficio/perdida, precio de apertura, así como otras características que tienen las órdenes (precios de parada, hora y razón de cierre, etc) no se tienen en cuenta.

	Todas las órdenes de un determinado tipo deben cerrarse de mayor a menor cantidad de lotes, si el criterio para cerrar las órdenes se ha activado. 


Para realizar la secuencia de cierre, en el bloque 3-4, se utiliza el ciclo “for”, en el cual (en volumen) la orden mas grande se selecciona entre las demás ordenes del mismo tipo. Este análisis se hace sobre el array global Mas_Ord_New que contiene la información de todas las órdenes abiertas. Después de que el número de identificación de la orden se haya detectado, según el tipo de orden, el precio más cercano de cierre es según el último precio de doble vía. Si el tipo de orden que hay que cerrar es de compra, el precio debe solicitarse sobre el valor “Bid”. Si son órdenes de venta, debe utilizarse el valor “Ask”. 

Justo antes de hacer la solicitud al bróker, se muestra un mensaje que comunica que se está haciendo un intento de cerrar una orden. Para esto se llama a la función Inform(). La solicitud para cerrar una orden se forma en la siguiente línea:
      bool Ans=OrderClose(Ticket,Lot,Price_Cls,2);// Cerrar orden!:)
Se utilizan los siguientes valores como parámetros: Ticket – numero de la orden, Lot – volumen de lotes, Price_Cls – precio de cierre, 2 – deslizamiento del precio. 

En el bloque 4-5, se analizan los resultados de la operación. Si la función OrderClose() ha devuelto “true”, significa que la operación se realizo correctamente, es decir, se ha cerrado la orden. En este caso, el programa salta al bloque 5 – 6, donde se actualiza la información de las ordenes abiertas. En cada iteración del ciclo externo “while”, se ejecutan las funciones Terminal() y Events()  (la cantidad de órdenes abiertas puede cambiar mientras se ejecuta la función y durante las operaciones, por lo que la ejecución de la función que lleva la contabilidad es obligatoria en cada iteración del ciclo“while”). Si todavía llegara haber ordenes abiertas de un tipo dado, estas se cerraran en las siguientes iteraciones del ciclo “while”, ya que la lista de las ordenes abiertas Mas_Ord_New  y la lista con la cantidad de tipos de ordenes abiertas Mas_Tip, se actualizan cada vez que se ejecuta la función Terminal().

Si la función OrderClose() devuelve “false”, esto significa que no se ha cerrado la orden. Para saber los motivos de este error, el programa analiza el último error dado al hacer una operación. Para eso se ejecuta la función Errors() (véase Función para el procesamiento de errores LINK). Si esta función detecta que el error es crítico (por ejemplo, la operación está prohibida), la función Close_All() termina su ejecución y le devuelve el control a la función Trade(), dando como resultado final que la función especial del EA, start() también termine su ejecución. En el siguiente Tic, el terminal ejecutara nuevamente la función start(). Si el criterio comercial para el cierre permanece activo, se ejecutara nuevamente la función que cierra todas las ordenes Close_All ().
Función definida por el usuario Open_Ord()
int Open_Ord ( int Tip)
La función abre una orden de un tipo dado.

El parámetro TIP debe recibir los siguientes valores que representara el tipo de orden a abrir. 

0 – Se abrirá una orden de compra;

1 - Se abrirá una orden de venta.

Para ejecutar esta función, es necesario utilizar varias funciones que ya hemos visto, como la función que lleva las ordenes Terminal(), la que maneja los eventos Events() y la que procesa los errores Errors(). También para mostrar los mensajes en pantalla utilizaremos la función Inform(). Si la función Inform() no se incluye en el EA, no aparecerá ningún mensaje .

Las siguientes variables globales se utilizarán:

· Mas_Tip - El array que lleva el listado de los diferentes tipos de órdenes abiertas y la cantidad de cada tipo de orden desde la última ejecución de la función Terminal(); 

· StopLoss - el valor del StopLoss (en pips); 

· TakeProfit - el valor del TakeProfit (en pips). 

La función ejecutiva Open_Ord()se guardara en el archivo Open_Ord.mqh:
//---------------------------------------------------------------------------------
// Open_Ord.mqh
// Este código solo debe ser usado de manera educacional.
//---------------------------------------------------------------------------- 1 --
// Función que abre ordenes de un tipo dado.

// Variables globales:

// int Mas_Tip Array con tipo y cantidad de ordenes

// int StopLoss El valor del StopLoss (en pips);

// int TakeProfit El valor del TakeProfit (en pips).
//---------------------------------------------------------------------------- 2 --
int Open_Ord(int Tip)
  {
   int    Ticket,                        // Numero de orden
          MN;                            // Numero magico
   double SL,                            // StopLoss (con respecto al precio)
          TP;                            // TakeProf (con respecto al precio)
//---------------------------------------------------------------------------- 3 --
   while(Mas_Tip[Tip]==0)                // Hasta que..
     {                                   //.. hecho
      if (StopLoss<Level_new)            // Si es menos que el permitido...
         StopLoss=Level_new;             // .. entonces es permitido
      if (TakeProfit<Level_new)          // Si es menos que el permitido..
         TakeProfit=Level_new;           // .. entonces es permitido
      MN=TimeCurrent();                  // Simple numero magico
      Inform(13,Tip);                    // Mensaje acerca de intentar abrir una orden 
      if (Tip==0)                        // Vamos a comprar
        {
         SL=Bid - StopLoss*  Point;      // StopLoss   (precio)
         TP=Bid + TakeProfit*Point;      // TakeProfit (precio)
         Ticket=OrderSend(Symbol(),0,Lots_New,Ask,2,SL,TP,"",MN);
        }
      if (Tip==1)                        // Vamos a vender
        {
         SL=Ask + StopLoss*  Point;      // StopLoss   (precio)
         TP=Ask - TakeProfit*Point;      // TakeProfit (precio)
         Ticket=OrderSend(Symbol(),1,Lots_New,Bid,2,SL,TP,"",MN);
        }
      //---------------------------------------------------------------------- 4 --
      if (Ticket<0)                       // Fallo:( 
        {                                 // Se revisa el error:
         if(Errors(GetLastError())==false)// si el error es crítico,
            return;                       // .. se sale.
        }
      Terminal();                         // Orden para llevar la contabilidad
      Events();                           // Seguimiento de eventos
     }
//---------------------------------------------------------------------------- 5 --
   return;                                // Se sale de la función
  }
//---------------------------------------------------------------------------- 6 --
En el bloque 1-3 de la función Open_Ord(), las variables globales se describen, y se inicializan y describen  las variables locales. La mayoría del código se concentra en el ciclo “while” (bloques 3-5) que se ejecuta mientras no haya operaciones abiertas del mismo tipo. 

Uno de los requisitos de esta estrategia comercial, es que las órdenes abiertas deben tener precios de parada diferentes a cero. Es común que se den casos en que los precios de parada estén más cercanos que lo permitido por el servidor del bróker. Por esta razón se realizan las comprobaciones necesarias antes de abrir una orden. Si el valor de las variables externas StopLoss o TakeProfit es menor que lo permitido por la distancia mínima (Level_new),  entonces el valor de estas variables se iguala al valor de la distancia mínima que está en Level_new. 

Cada orden abierta tiene un número mágico único, que es igual a la hora actual del servidor. Este EA solo permite tener una orden abierta  (o colocada, si se trata de un pedido pendiente) a la vez. Esto causa que todas las órdenes abiertas tengan un número mágico único. Antes de abrir una orden, la función Inform() se ejecuta, mostrando un mensaje que informa sobre el intento de abrir una orden.

Según el tipo de orden, se ejecuta alguna de las dos condiciones “if”. Por ejemplo, si el valor del parámetro recibido es 0, significa que se debe comprar. En este caso, los valores de StopLoss y TakeProfit se calculanen base a la orden de compra, y a continuación se pasa a la línea…
         Ticket=OrderSend(Symbol(),0,Lots_New,Ask,2,SL,TP,"",MN);

para hacer la petición de compra. Cálculos similares se hacen si el parámetro es 1, ósea una venta. 

Los errores en las funciones ejecutivas se procesan igual. Si la operación se completa con éxito, la función finaliza sus operaciones (porque el ciclo “while” solo funciona cuando Mas_Tip[Tip] es igual a 0, y al ejecutarse la función Terminal() cuando se ha tenido éxito abriendo una orden, Mas_Tip[Tip] será igual a 1). Sin embargo, si la orden no se realiza, se analizan los errores (bloque 4-5). En este caso, se llama a la función Errors() para que analice el error. Si devuelve “false” (el error es crítico), la ejecución de la función Open_Ord() finaliza y el control se devuelve a la función Trade(), y luego a la función especial start(), y a continuación al terminal del cliente. Sin embargo, si el error no es crítico, se actualiza el listado de ordenes abiertas con la función Terminal (), lo que se traduce en un nuevo intento para abrir  la orden. 

Por lo tanto, la función Open_Ord () tiene el control hasta que se abre una orden o se produce un error crítico en la ejecución de la solicitud.
Función definida por el usuario Tral_Stop()
int Tral_Stop ( int Tip)
Esta función modifica todas las órdenes de un tipo dado.

El parámetro TIP debe recibir los siguientes valores que representara el tipo de orden a modificar. 

0 – Se modificara una orden de compra;

1 - Se modificara una orden de venta.

Para ejecutar esta función, es necesario utilizar varias funciones que ya hemos visto, como la función que lleva las ordenes Terminal(), la que maneja los eventos Events() y la que procesa los errores Errors(). También para mostrar los mensajes en pantalla utilizaremos la función Inform(). Si la función Inform() no se incluye en el EA, no aparecerá ningún mensaje .

Las siguientes variables globales se utilizarán:

· Mas_Ord_New - Array con las características de las órdenes abiertas desde la última ejecución de la función Terminal(); 

· TralingStop - La distancia entre el precio del mercado y el precio deseado para el StopLoss (numero de pips).
La función ejecutiva Tral_Stop() se guarda en un archivo para incluir después Tral_Stop.mqh:
//---------------------------------------------------------------------------------
// Tral_Stop.mqh
// Este código solo debe ser usado de manera educacional.
//---------------------------------------------------------------------------- 1 --
// Función que modifica el StopLoss de todas las ordenes de un tipo dado
// Variables globales:
// Mas_Ord_New             Array con listado de ordenes
// int TralingStop         Valor del TralingStop (cantidad en pips)
//---------------------------------------------------------------------------- 2 --
int Tral_Stop(int Tip)
  {
   int Ticket;                      // Numero de la orden
   double
   Price,                           // Precio de orden abierta
   TS,                              // TralingStop (con respecto al precio)
   SL,                              // Valor del StopLoss de la orden
   TP;                              // Valor del TakeProfit de la orden
   bool Modify;                     // Criterio a modificar
//---------------------------------------------------------------------------- 3 --
   for(int i=1;i<=Mas_Ord_New[0][0];i++)  // Ciclo en todas las ordenes
     {                                    // Busca en les orden es de un tipo dado
      if (Mas_Ord_New[i][6]!=Tip)         // Si no es del tipo…
         continue;                        //.. salta a la siguiente orden
      Modify=false;                       // No se asigna para ser modificada
      Price =Mas_Ord_New[i][1];           // Precio de orden abierta
      SL    =Mas_Ord_New[i][2];           // StopLoss de la orden
      TP    =Mas_Ord_New[i][3];           // TakeProft de la orden
      Ticket=Mas_Ord_New[i][4];           // numero de la orden
      if (TralingStop<Level_new)          // Si es menor que permitido..
         TralingStop=Level_new;           // .. entonces permitido
      TS=TralingStop*Point;               // Lo mismo relativo al precio
      //---------------------------------------------------------------------- 4 --
      switch(Tip)                         // Ir al tipo de orden
        {
         case 0 :                         // Orden de compra
            if (NormalizeDouble(SL,Digits)<// Si es menor a lo deseado..
               NormalizeDouble(Bid-TS,Digits))
              {                           // .. entonces modificar:
               SL=Bid-TS;                 // este nuevo StopLoss
               Modify=true;               // Asignado para modificación.
              }
            break;                        // Se sale del 'switch'
         case 1 :                         // Orden de venta
            if (NormalizeDouble(SL,Digits)>// Si es mayor a lo deseado..
               NormalizeDouble(Ask+TS,Digits)||
               NormalizeDouble(SL,Digits)==0)//.. o cero (!)
              {                           // .. entonces modificar:
               SL=Ask+TS;                 // este nuevo StopLoss
               Modify=true;               // Asignado para modificación..
              }
        }                                 // Se sale del 'switch'
      if (Modify==false)                  // Si no está asignado para modificar..
         continue;                        // .. entonces continúe el ciclo
      bool Ans=OrderModify(Ticket,Price,SL,TP,0);//Modificar!
      //---------------------------------------------------------------------- 5 --
      if (Ans==false)                     // Fallo :( 
        {                                 // Revisa los errores:
         if(Errors(GetLastError())==false)// Si el error es crítico,
            return;                       // .. entonces se sale.
         i--;                             // Decrece la cuenta
        }
      Terminal();                         // Función que lleva la contabilidad
      Events();                           // Función que rastrea los eventos
     }
   return;                                // Salimos de la función
  }
//---------------------------------------------------------------------------- 6 --
En el bloque 1 – 3, se describen las variables globales que se están usando en la función, como también las variables locales. En el ciclo “for” (bloques 3-6), se selecciona las ordenes de un tipo dado, y si el StopLoss de cualquiera de las ordenes esta mas lejos que lo establecido por el usuario, se modifica la orden.  

Para que el código sea más legible, los valores de algunos elementos de la array Mas_Ord_New se asignan a unas simples variables (bloque 3-4). A continuación, se hará una comprobación necesaria para la variable TralingStop: Si el valor de esta variable es menor que la distancia mínima permitida fijada por el servidor del bróker, se igualará con la distancia mínima. 

En el bloque 4 -5, según el tipo de orden, se hacen los cálculos necesarios. Por ejemplo, si el valor del parámetro recibido Tip es 1 (una orden de venta debe ser modificada), el control será pasado al “caso 1” del operador “switch”. Si es necesario modificar el StopLoss se comprueba aquí (de acuerdo con las reglas aplicadas a este tipo de órdenes, vea los requisitos y limitaciones de la creación de ordenes LINK). Si no se fija ningún StopLoss o si se fija en una distancia mayor de TralingStop al precio actual, se calcula en nuevo valor para el StopLoss. La solicitdud para cambiar la orden se forma en la línea:
      bool Ans = OrderModify(Ticket,Price,SL,TP,0);//Modificar!
Vimos antes que esta estrategia comercial solo permite la posibilidad de tener una sola cuenta abierta. Sin embargo, la función Tral_Stop()está diseñada para aceptar varias órdenes. Si el operador no interviene manualmente en las órdenes durante el funcionamiento del EA, no habrá necesidad de modificar varias órdenes. Sin embargo, si el operador abre una orden manualmente (además de tener una orden ya abierta), se deberá decidir cuales ordenes deben modificarse primero y porque. 

Cuando enfrentamos una situación parecida al cerrar varias órdenes, dijimos que las ordenes se cerrarían según la mayor cantidad de lotes. Esta solución es obvia – los lotes mayores (de la cantidad total) es mejor cerrarlos antes que se desactive el criterio comercial del EA. El problema para decidir el orden de modificación no tiene una única solución. En todos los casos, el orden para modificar las órdenes debe estar determinado por la esencia de la estrategia. El criterio puede ser la cantidad de lotes, o la falta de StopLoss en una de las órdenes, o la distancia del StopLoss sobre el precio actual. En unos casos, este criterio se puede expresar en un índice total – el tamaño de la perdida que pueden resultar después de movimientos agudos del precio, es decir,  cuando todas las ordenes de mercado son cerradas automáticamente por el StopLoss al mismo tiempo. 

En el ejemplo anterior en la función Tral_Stop(), las ordenes se modifican sin ningún orden en particular, las ordenes se modifican según el orden de llegada. Según sea el caso, el programador debe tener en cuenta el orden de modificación, según sea conveniente para cada estrategia. 

Debe prestarse especial atención al hecho que todas las órdenes se realizan en tiempo real. Si hay demasiadas ordenes, el EA generara una gran variedad de peticiones al servidor. Obviamente, el mercado puede darse vuelta en el mismo instante que se están ejecutando estas peticiones. Sin embargo, la función no devolverá el control a la función Trade(), hasta que se modifiquen todas las ordenes solicitadas. Esto significa que existe el peligro que mientras se está modificando las órdenes, no se puedan abrir ni cerrar órdenes cuando se active un criterio comercial. Por esta razón, cualquier estrategia debe procurar no tener tantas órdenes abiertas al mismo tiempo. 

En el bloque de 5-6, se revisan los errores durante la ejecución de la operación. Si el error es crítico, la función terminará su ejecución. Sin embargo, si se produce un error no critico, el valor del contador 'i' se reduce en 1. De esta manera se producirá un nuevo intento para modificar la misma orden en la siguiente iteración del ciclo 'for'.

En la mayoría de los casos, el código anterior servirá para modificar varias órdenes. Al mismo tiempo, si hay cambios en las ordenes (por ejemplo una orden será cerrada cuando el precio de mercado alcanza uno de los niveles de parada) mientras se hacen varios intentos fallidos de modificar una orden, la secuencia de ordenes en el array Mas_Ord_New puede cambiar. Esto dará como resultado que una orden sea omitida y no se modifique hasta la próxima ejecución de la función especial start(). Esta situación se puede arreglaren en el siguiente tip, durante la próxima ejecución de la función start().

En la mayoría de los casos, el código antedicho se conformará con la necesidad para modificar varias órdenes. Al mismo tiempo, si algunos cambios ocurren en las órdenes (por ejemplo, una orden será cerrada cuando el precio de mercado alcanza uno de los niveles de la parada) dentro del período de varios intentos fallidos de modificar órdenes, la secuencia de órdenes en el arsenal Mas_Ord_New puede también cambiar. Esto resultará en que una orden no se puede omitir y modificar dentro del período del lanzamiento pasado del comienzo de la función especial (). Esta situación se puede mejorar en la señal siguiente, en el lanzamiento siguiente del comienzo de la función ().

En la mayoría de los casos, el código anterior se de acuerdo con la necesidad de modificar las órdenes de varias. Al mismo tiempo, si los cambios celebrarse en los pedidos (por ejemplo, un pedido se cerrará cuando el precio de mercado alcanza uno de los niveles parada) dentro del período de varios intentos para modificar las órdenes, la secuencia de órdenes en la matriz de fallidos También puede cambiar Mas_Ord_New. Esto dará lugar en que un pedido puede ser se omite y no modificado en el plazo del último lanzamiento de la función especial start(). Esta situación puede mejorarse en la siguiente garrapata, durante la próxima presentación de la función start().
Función para el procesado de errores
Los errores que aparecen durante la ejecución de funciones ejecutivas, se pueden dividir en dos grupos- errores no críticos y errores críticos. Errores no críticos son los errores del servidor. Después de haberse solucionado estos errores, se puede continuar con las operaciones. Por ejemplo, una orden puede ser rechazada por el servidor, si no hay información sobre los precios actuales del mercado. Este tipo de situaciones puede aparecer en un mercado lento, es decir, cuándo llegan pocos tics. O por el contrario, el servidor del bróker puede bloquearse cuando se están haciendo demasiadas  operaciones al mismo tiempo. Por esta razón puede pasar un tiempo antes que se ejecute la orden,  o a veces una negación de la operación. En tales casos, el EA puede continuar funcionando, y por ejemplo, repetir la petición un poco después de la ejecución de algún código que procese el error. 
Los errores críticos incluyen todos los errores que alerten de problemas serios. Por ejemplo, si se bloquea una cuenta, es imposible hacer operaciones. En tal caso, el EA debe mostrar el mensaje correspondiente y no debería repetir la petición. Por estos motivos, es indispensable tener una función en el EA que procese los errores.
Función definida por el usuario Errors()
bool Errors( int Error )
Esta función devuelve “true”  si el error no es crítico. Si no devuelve “false”.

El parámetro error puede tener cualquier valor y este valor corresponde al tipo de error que se produjo al intentar hacer la operación. The function returns TRUE, if the error is overcomable. Otherwise, it returns FALSE. 
Esta función definida por el usuario se incluye en el archivo Errors.mqh:
//--------------------------------------------------------------------
// Errors.mqh
// Este código solo debe ser usado de manera educacional.
//--------------------------------------------------------------- 1 --
// Función que procesa los errores.

// Valores devueltos:

// true – Si es error no es crítico (se pueden continuar intentando)

// false – Si el error es crítico (es imposible operar)
//--------------------------------------------------------------- 2 --
bool Errors(int Error)                    // Función definida por el usuario. 
  {
   // Error             // Numero del error   
   if(Error==0)
      return(false);                      // No hay error 
   Inform(15,Error);                      // Mensaje
//--------------------------------------------------------------- 3 --
   switch(Error)
     {   // Errores no críticos:
      case 129:         // Precio incorrecto 
      case 135:         // Precio cambiado 
         RefreshRates();                  // Actualiza datos 
         return(true);                    // El error no es critico 
      case 136:         // No hay precios. Esperar la próxima señal 
         while(RefreshRates()==false)     // Antes del nuevo tick 
            Sleep(1);                     // demora en el ciclo 
         return(true);                    // Error en no critico 
      case 146:         // El servidor está ocupado 
         Sleep(500);                      // Solución simple 
         RefreshRates();                  // Actualiza datos
         return(true);                    // El error no es critico
         // Errores críticos::
      case 2 :          // Error común
      case 5 :          // El terminal tiene una versión vieja
      case 64:          // Cuenta bloqueada 
      case 133:         // Operar está prohibido 
      default:          // Otras variantes
         return(false);                   // Error critico 
     }
//--------------------------------------------------------------- 4 --
  }
//--------------------------------------------------------------------
Una de las preguntas que se presentan al escribir el código de la función Errors() es: ¿Qué valor debería devolver la función si el valor recibido es 0? (es decir, no hay errores). Esta clase de situaciones no debe aparecer en un EA correctamente escrito. Sin embargo, el código puede ir modificándose mientras que se desarrolla el programa, así que a veces el valor de un error puede ser igual a 0. Así pues es razonable colocar unas líneas de más, en esta función en la etapa de desarrollo (bloque 2-3), para las situaciones donde el error es igual a 0.
La reacción de la función Errors() ante el valor 0, depende del código usado para procesar los valores devueltos por la función. El valor devuelto por la función se toma en cuenta en la función comercial ejecutada antes, en el EA. Si la función Errors() devuelve “true” (error no critico), entonces, el programa volverá a intentar hacer la operación. Si devuelve “false”, entonces se detiene la función ejecutiva, y el control se devuelve así sucesivamente a la función precedente, hasta llegar a la función start() y luego al cliente de terminal. Si la opción no está en ninguna de estas dos alternativas, entonces, en la situación cuando no hay errores (error = 0) corresponderá  a la segunda alternativa, a saber, el valor devuelto será “false”. Esto garantiza que no se repita la solicitud.

Una vez que el mensaje de error ha sido mostrado por la función Inform(), el programa salta al bloque 3-4, al operador “switch”. En cada caso hay un código que maneja el error tratado. Por ejemplo, si ocurre el error 136, significa que el servidor no tiene precios actuales para poder tomar así una decisión apropiada. Esto significa que la situación no cambiará a menos que venga una nuevo tick, así que no hay necesidad de repetir la misma operación porque no se ejecutara de todas formas el envió. La solución correcta en este caso es hacer una pausa – pausar cualquier acción del EA. Un método sencillo para detectar un nuevo tick se utiliza con este fin – el análisis del valor devuelto por la función RefreshRates().El control será devuelto la función a la función de llamada, en la cual se repite la operación (tras el análisis correspondiente, si es necesario), tan pronto como se reciba un nuevo tick.

Si hay un error que el programar considerara critico, la función devolverá “false”. La orden no se repetirá, en tal caso, así que no hay necesidad de hacer algo en la función de Errors(). Todos los errores que no se procesan son considerados críticos por defecto. Se pueden ampliar la lista de errores procesados (ver códigos de error LINK).

